열 범위에만 셀 추가

Question

기존 목록 (Col B)에 값을 추가하는 매크로 (VBA/작성 코드 신규)를 작성하려고합니다. 값은 InputBox에 의해 정의 된 다음 사전 순으로 목록에 추가됩니다. 매크로를 작동시킬 수 있지만 전체 행 대신 범위에 셀을 추가하고 싶습니다.

내 스프레드 시트에는 열 A부터 K까지의 데이터가 있습니다.이 열은 '행'을 삽입하려는 영역입니다. 그러나 캐치가 있습니다. 열을 추가하지 않으려는 열 L에서 AF까지 다른 데이터 집합이 있습니다. 이것은 내가 완전한 행을 삽입 할 수 있기 때문에 내가 실패한 곳입니다.

이 방법이 있습니까? 삽입 할 위치를 선택하지 못하게하는 새로운 값의 위치 (알파벳순)에 따라 삽입이 수행되어야하는 것처럼 보이는 모든 메서드에서 실행되지 않았습니다. 나는 코드를보기 위해 매크로 기록을 시도했으나 그 값에 의해 정의 된 선택 때문에 그 입력을 조작 할 수 없었다.

여기 제가 지금까지 가지고있는 코드는 ... 제가 아직 배우고있는 것처럼 조금 clunky 수 있습니다.

Sub Add_Project() 
Dim NewProject As String, iRow As Long, ProjRng As Range, RowRng As Range 
'The ProjRng MUST represent the project column! 
    Set ProjRng = Range("B:B") 
'Defines the range of columns to add a row to 
    Set RowRng = Range("B:K") 
'Create message box for user input on project name 
    NewProject = InputBox("Enter Project Name") 
    If NewProject = "" Then Exit Sub 
'Determines if the New Project name already exists 
    iRow = Application.WorksheetFunction.Match(NewProject, ProjRng) 
    If Cells(ProjRng.row + iRow - 1, ProjRng.Column) = NewProject Then 
     MsgBox ("Project already exists") 
Exit Sub 
    End If 
'Inserts a new row with containing the new Project name 
    With Cells(ProjRng.row + iRow, ProjRng.Column) 
     .EntireRow.Insert 
     .Offset(-1, 0).Value = NewProject 
    End With 
Exit Sub 
End Sub 

매크로가 내가 지시 한대로하고 있다는 것을 알고 있습니다. 나는 칼럼 A : K의 범위에만 추가하는 것과 함께 "EntireRow"를 추가하는 섹션을 조작하고 싶습니다. 내가 제안 할 수있는 곳에 대한 제안이나 조언은 많은 도움이 될 것입니다. 감사합니다.

Answer 1

Sub Add_Project() 

    Dim strNewProject As String 
    Dim iRow As Long 

    strNewProject = InputBox("Enter Project Name") 
    If Len(strNewProject) = 0 Then Exit Sub 'Pressed cancel 

    If WorksheetFunction.CountIf(Columns("B"), strNewProject) > 0 Then 
     MsgBox "Project already exists" 
     Exit Sub 
    End If 

    iRow = WorksheetFunction.Match(strNewProject, Columns("B")) + 1 
    Intersect(Range("A:K"), Rows(iRow)).Insert xlShiftDown 
    Cells(iRow, "B").Value = strNewProject 

End Sub