VBA에서 FileSystemObject를 사용하여 텍스트 파일의 줄에 문자열을 바꾸려면 어떻게해야합니까?

Question

FileSystemObject 메서드를 사용하여 텍스트 파일의 특정 줄을 찾고 해당 줄 내에서 특정 문자열을 바꿔 봅니다. 나는 현재 비교적 익숙하지 않은데, 현재 코드가 텍스트 파일을 여는 데 탁월한 능력을 발휘하고 내가 필요로하는 것을 바꿔서 저장하고 닫는다. 이 방법은 더 이상 옵션이 아닙니다. 텍스트 파일을 여는 데 시간이 오래 걸리므로 파일을 보관할 수 있습니다.

이것은 지금까지 내가 지금까지 얻은 것입니다.

-

Sub FindLines() 

Const ForReading = 1 

Set FSO = CreateObject("Scripting.FileSystemObject") 

Set objFSO = FSO.OpenTextFile("C:\Users\Carella Home\Desktop\boomboom.txt", ForReading,  False) 

Do Until objFSO.AtEndOfStream = True 

    go = objFSO.ReadLine 

    If InStr(1, go, "ant", vbTextCompare) > 0 Then 

     bo = Replace(go, "t", "wow") 

    End If 

Loop 

objFSO.Close 

Set objFSO = FSO.OpenTextFile("C:\Users\Carella Home\Desktop\boomboom.txt", 2) 

End Sub 

-

내가 할 수있는 최선가 작성하는 최대 파일 열기,하지만 난 어떻게 선을 찾아 내가 필요 라인으로 교체하는 아무 생각이 없다 그것으로 대체하십시오.

올바른 방향으로 나를 도와주고 싶다면 더 많은 정보가 필요하면 알려주십시오. 나는 많은 것을 수색하고 사람들이 이것을하는 다른 방법을 제안하는 것을 보았다. 이 방법으로 줄을 편집하는 방법을 배워야합니다. 누군가 나를 도울 수 있습니까?

미리 감사드립니다.

-Anthony C.

Answer 1

이 가장 효율적인 방법입니다하지만 하나의 생각은 당신이 쓸 수있는 다른 파일을 만들려면 FileSystemObject의 CreateTextFile 방법을 사용하는 것입니다 확실하지.

이 파일은 작은 파일로 테스트했으며 예상대로 작동하는 것 같습니다.

대답은 당신이 "원래"제거 할 것인지 여부에 따라 다음 .ReadLine 및 .WriteLine 루프

Sub FindLines() 
'Declare ALL of your variables :) 
Const ForReading = 1 ' 
Const fileToRead As String = "C:\Users\david_zemens\Desktop\test.txt" ' the path of the file to read 
Const fileToWrite As String = "C:\Users\david_zemens\Desktop\test_NEW.txt" ' the path of a new file 
Dim FSO As Object 
Dim readFile As Object 'the file you will READ 
Dim writeFile As Object 'the file you will CREATE 
Dim repLine As Variant 'the array of lines you will WRITE 
Dim ln As Variant 
Dim l As Long 

Set FSO = CreateObject("Scripting.FileSystemObject") 
Set readFile = FSO.OpenTextFile(fileToRead, ForReading, False) 
Set writeFile = FSO.CreateTextFile(fileToWrite, True, False) 

'# Read entire file into an array & close it 
repLine = Split(readFile.ReadAll, vbNewLine) 
readFile.Close 

'# iterate the array and do the replacement line by line 
For Each ln In repLine 
    ln = IIf(InStr(1, ln, "ant", vbTextCompare) > 0, Replace(ln, "t", "wow"), ln) 
    repLine(l) = ln 
    l = l + 1 
Next 

'# Write to the array items to the file 
writeFile.Write Join(repLine, vbNewLine) 
writeFile.Close 

'# clean up 
Set readFile = Nothing 
Set writeFile = Nothing 
Set FSO = Nothing 

End Sub 

을 피하기 위해 접수 후 할 수있는 파일을 수정 뭔가 같은 :

'# clean up 
Set readFile = Nothing 
Set writeFile = Nothing 
'# Get rid of the "old" file and replace/rename it with only the new one 
Kill fileToRead 
Name fileToWrite As fileToRead 
End Sub 

Answer 2

여기에 비해 훨씬 빠르고 더 짧은 방법입니다.

Sub Sample() 
    Dim MyData As String, strData() As String 

    '~~> Read the file in one go! 
    Open "C:\Users\Carella Home\Desktop\boomboom.txt" For Binary As #1 
    MyData = Space$(LOF(1)) 
    Get #1, , MyData 
    Close #1 
    strData() = Split(MyData, vbCrLf) 
End Sub 

모든 텍스트 파일 데이터가 배열 strData에 있습니다. 배열을 반복하고 바꾸고 싶은 텍스트를 찾아서 SAME 파일에 다시 쓰십시오.