PowerPoint VBA : 어떤 명령 (또는 명령 집합)이 내 .jpg 그림에서 ppt 프레임을 만들 수 있습니까?

Question

나는 C에서 몇 .JPG 파일이 : pic_1.jpg, pic_2.jpg, pic_3.jpg, pic_4.jpg, pic_5.jpg : my_folder

다음

그들의 이름 \.

PowerPoint에서 자동으로 여러 프레임을 만들어 각 프레임에 그림이 하나씩 포함되도록하려면 Power Point VBA의 어떤 명령 또는 명령 그룹을 사용해야합니까?

Answer 1

이 VBScript는 새로운 PowerPoint 프레젠테이션을 만들고 각 PowerPoint 프레젠테이션에 두 개의 슬라이드를 추가합니다. 취향에 맞게 그림의 위치와 크기를 조정해야합니다. 또한 프리젠 테이션에 삽입 할 디렉토리에있는 모든 그림을 자동으로 잡으려는 경우 Scripting.FileScriptingObject를 사용하여 이미지를 열거해야합니다. 슬라이드가 생성 된 후 pptPresentation.SaveAs을 호출하여 프리젠 테이션을 저장할 수도 있습니다.

MSDN 설명서는 http://msdn.microsoft.com/en-us/library/ff746873.aspx에 있습니다. 이전의 대답은 VBS 스크립트에 특이으로

Dim pptDoc 
Dim pptPresentation 
Dim pptSlide 

Set pptDoc = WScript.CreateObject("PowerPoint.Application") 
pptDoc.Visible = True 
Set pptPresentation = pptDoc.Presentations.Add(True) 

' Add a new slide with a blank layout to the end of the Slides collection 
' 12 = ppLayoutBlank 
Set pptSlide = pptPresentation.Slides.Add(pptPresentation.Slides.Count + 1, 12) 

' Add a picture into the slide, saving the picture into the PowerPoint document 
' 10, 10 are the Left and Top coordinates respectively 
pptSlide.Shapes.AddPicture "c:\FullPath\1.JPG", False, True, 10, 10 

' Add another slide with a picture 
Set pptSlide = pptPresentation.Slides.Add(pptPresentation.Slides.Count + 1, 12) 
pptSlide.Shapes.AddPicture "c:\FullPath\2.jpg", False, True, 10, 10 

Answer 2

는 여기에 VBA 매크로로 파워 포인트에 삽입하는 버전입니다. PowerPoint 2010에서 만들었습니다.

이 디렉터리에는 하드 코드가 있으므로 읽을 때 디렉터리 이름을 묻는 메시지가 표시됩니다.

Sub CreatePictureSlideshow() 
    Dim presentation 
    Dim layout 
    Dim slide 

    Dim FSO 
    Dim folder 
    Dim file 
    Dim folderName 

    ' Set this to point at the folder you wish to import JPGs from 
    ' Note: make sure this ends with a backslash \ 
    folderName = "c:\somedirectory\" 

    ' Delete all slides and setup variables 
    Set presentation = Application.ActivePresentation 
    If presentation.Slides.count > 0 Then 
    presentation.Slides.Range.Delete 
    End If 
    Set layout = Application.ActivePresentation.SlideMaster.CustomLayouts(1) 
    Set FSO = CreateObject("Scripting.FileSystemObject") 

    ' Retrieve the folder's file listing and process each file 
    Set folder = FSO.GetFolder(folderName) 
    For Each file In folder.Files 

    ' Filter to only process JPG images 
    If LCase(Mid(file.Name, Len(file.Name) - 3, 4)) = ".jpg" Then 

     ' Create the new slide and delete any pre-existing contents 
     Set slide = presentation.Slides.AddSlide(presentation.Slides.count + 1, layout) 
     While slide.Shapes.count > 0 
      slide.Shapes(1).Delete 
     Wend 

     ' Add the picture 
     slide.Shapes.AddPicture folderName + file.Name, False, True, 10, 10 

     ' Optional: create a textbox with the filename on the slide for reference 
     ' Dim textBox 
     ' Set textBox = slide.Shapes.AddTextbox(msoTextOrientationHorizontal, 10, 10, 200, 200) 
     ' textBox.TextFrame.TextRange.Text = file.Name 
    End If 
    Next 

End Sub