7 번째 줄에 선언 된 변수가있는 파일이 VERSION = 6.0.196.0입니다. 이 줄을 VERSION = 6.0.200.0배치 스크립트는 파일의 7 번째 줄에있는 텍스트를 바꿉니 까?
으로 편집하고 15 번째 줄을 MANIFEST_BUILD => 196으로 편집해야합니다. MANIFEST_BUILD => 200으로 변경해야합니다. 이 작업을 수행하는 방법?
7 번째 줄에 선언 된 변수가있는 파일이 VERSION = 6.0.196.0입니다. 이 줄을 VERSION = 6.0.200.0배치 스크립트는 파일의 7 번째 줄에있는 텍스트를 바꿉니 까?
으로 편집하고 15 번째 줄을 MANIFEST_BUILD => 196으로 편집해야합니다. MANIFEST_BUILD => 200으로 변경해야합니다. 이 작업을 수행하는 방법?
이 대답의 모든 솔루션은 Windows XP 이상의 기본 명령 만 사용합니다.
1)이 지금까지 가장 빠른 네이티브 배치 솔루션 가능하지만,이 파일의 처음 15 개 라인의
<carriageReturn><lineFeed>
(Windows 스타일)으로 끝나야하고 <lineFeed>
(유닉스 스타일)로 끝나야합니다. 처음 15 개 라인의XP 및 Windows 7에 대한 하나 개의 추가 제한이 있습니다 : 파일의 마지막 줄은 <lineFeed>
로 끝나야합니다 . FINDSTR의 버그로 인해 마지막 줄이 <linefeed>
으로 끝나지 않으면 스크립트가 무기한 중지됩니다. 자세한 내용은 What are the undocumented features and limitations of the Windows FINDSTR command?을 참조하십시오.
@echo off
setlocal enableDelayedExpansion
set "file=test.txt"
REM redirect input from your file and output to a new file
<"%file%" >"%file%.new" (
REM preserve lines 1-6
for /l %%N in (1 1 6) do (
set "ln="
set /p "ln="
echo(!ln!
)
REM replace the next line (7)
set /p "ln="
echo VERSION=6.0.196.0
REM preserve lines 8-14
for /l %%N in (8 1 14) do (
set "ln="
set /p "ln="
echo(!ln!
)
REM replace the next line (15)
set /p "ln="
REM The > below must be escaped
echo MANIFEST_BUILD =^>200
REM preserve the remaining lines
findstr "^"
)
REM replace your original file with the new file
>nul move /y "%file%.new" "%file%"
2)이 다음 옵션은 훨씬 느리지 만 제한 사항이 훨씬 적습니다.
:
와 함께 시작할 수 없습니다 이상 8191 바이트 ~보다 수, 출력의 모든 라인에 관계없이 종결의 어떤 종류의, <carriageReturn><lineFeed>
으로 종료됩니다 원본 파일이 사용되었습니다. 이 라인 :
시작할 수 있도록 제외
@echo off
setlocal disableDelayedExpansion
set "file=test.txt"
>"%file%.new" (
for /f "tokens=1* delims=:" %%A in ('findstr /n "^" "%file%"') do (
if %%A==7 (
echo VERSION=6.0.196.0
) else if %%A==15 (
echo MANIFEST_BUILD =^>200
) else echo(%%B
)
)
move /y "%file%.new" "%file%"
3)이 옵션은 옵션 2와 거의 동일하다. 옵션 2보다 느립니다.
@echo off
setlocal disableDelayedExpansion
set "file=test.txt"
>"%file%.new" (
for /f "delims=" %%A in ('findstr /n "^" "%file%"') do (
for /f "delims=:" %%B in ("%%A") do (
if %%B==7 (
echo VERSION=6.0.196.0
) else if %%B==15 (
echo MANIFEST_BUILD =^>200
) else (
set "ln=%%A"
setlocal enableDelayedExpansion
echo(!ln:*:=!
endlocal
)
)
)
)
move /y "%file%.new" "%file%"
4)이 마지막 옵션은 훨씬 강력합니다. 텍스트 파일을 처리하는 데 사용할 수있는 하이브리드 JScript/Batch 유틸리티 스크립트를 사용합니다. 이 스크립트는 여전히 모든 최신 Windows 플랫폼 (XP 이후)의 기본 명령 만 사용합니다.
이 옵션은 옵션 1보다 느리지 만 합리적인 시간 내에 매우 큰 파일을 처리 할 수 있습니다. 옵션 2와 3보다 훨씬 빠르며, 큰 파일의 경우 너무 느립니다.
또한이 옵션을 사용하면 원본 파일에있는 줄 종결자가 유지됩니다.
이 옵션의 제한 사항을 알지 못합니다.
다음은 내 REPL에 의존하는 스크립트입니다.BAT 유틸리티
@echo off
set "file=test.txt"
findstr /n "^" "%file%" | repl "^(7:.*)" "VERSION=6.0.196.0" m | repl "^(15:.*)" "MANIFEST_BUILD =>200" m | repl "^\d*:" "" m>"%file%.new"
>nul move /y "%file%.new" "%file%"
그리고 위의 스크립트에서 필요한 REPL.BAT 유틸리티가 있습니다. REPL.BAT는 PATH의 다른 곳에 배치해야합니다. 전체 문서는 스크립트 내에 내장되어 있습니다.
@if (@X)==(@Y) @end /* Harmless hybrid line that begins a JScript comment
::************ Documentation ***********
:::
:::REPL Search Replace [Options [SourceVar]]
:::REPL /?
:::
::: Performs a global search and replace operation on each line of input from
::: stdin and prints the result to stdout.
:::
::: Each parameter may be optionally enclosed by double quotes. The double
::: quotes are not considered part of the argument. The quotes are required
::: if the parameter contains a batch token delimiter like space, tab, comma,
::: semicolon. The quotes should also be used if the argument contains a
::: batch special character like &, |, etc. so that the special character
::: does not need to be escaped with ^.
:::
::: If called with a single argument of /? then prints help documentation
::: to stdout.
:::
::: Search - By default this is a case sensitive JScript (ECMA) regular
::: expression expressed as a string.
:::
::: JScript syntax documentation is available at
::: http://msdn.microsoft.com/en-us/library/ae5bf541(v=vs.80).aspx
:::
::: Replace - By default this is the string to be used as a replacement for
::: each found search expression. Full support is provided for
::: substituion patterns available to the JScript replace method.
::: A $ literal can be escaped as $$. An empty replacement string
::: must be represented as "".
:::
::: Replace substitution pattern syntax is documented at
::: http://msdn.microsoft.com/en-US/library/efy6s3e6(v=vs.80).aspx
:::
::: Options - An optional string of characters used to alter the behavior
::: of REPL. The option characters are case insensitive, and may
::: appear in any order.
:::
::: I - Makes the search case-insensitive.
:::
::: L - The Search is treated as a string literal instead of a
::: regular expression. Also, all $ found in Replace are
::: treated as $ literals.
:::
::: E - Search and Replace represent the name of environment
::: variables that contain the respective values. An undefined
::: variable is treated as an empty string.
:::
::: M - Multi-line mode. The entire contents of stdin is read and
::: processed in one pass instead of line by line.^anchors
::: the beginning of a line and $ anchors the end of a line.
:::
::: X - Enables extended substitution pattern syntax with support
::: for the following escape sequences:
:::
::: \\ - Backslash
::: \b - Backspace
::: \f - Formfeed
::: \n - Newline
::: \r - Carriage Return
::: \t - Horizontal Tab
::: \v - Vertical Tab
::: \xnn - Ascii (Latin 1) character expressed as 2 hex digits
::: \unnnn - Unicode character expressed as 4 hex digits
:::
::: Escape sequences are supported even when the L option is used.
:::
::: S - The source is read from an environment variable instead of
::: from stdin. The name of the source environment variable is
::: specified in the next argument after the option string.
:::
::************ Batch portion ***********
@echo off
if .%2 equ . (
if "%~1" equ "/?" (
findstr "^:::" "%~f0" | cscript //E:JScript //nologo "%~f0" "^:::" ""
exit /b 0
) else (
call :err "Insufficient arguments"
exit /b 1
)
)
echo(%~3|findstr /i "[^SMILEX]" >nul && (
call :err "Invalid option(s)"
exit /b 1
)
cscript //E:JScript //nologo "%~f0" %*
exit /b 0
:err
>&2 echo ERROR: %~1. Use REPL /? to get help.
exit /b
************* JScript portion **********/
var env=WScript.CreateObject("WScript.Shell").Environment("Process");
var args=WScript.Arguments;
var search=args.Item(0);
var replace=args.Item(1);
var options="g";
if (args.length>2) {
options+=args.Item(2).toLowerCase();
}
var multi=(options.indexOf("m")>=0);
var srcVar=(options.indexOf("s")>=0);
if (srcVar) {
options=options.replace(/s/g,"");
}
if (options.indexOf("e")>=0) {
options=options.replace(/e/g,"");
search=env(search);
replace=env(replace);
}
if (options.indexOf("l")>=0) {
options=options.replace(/l/g,"");
search=search.replace(/([.^$*+?()[{\\|])/g,"\\$1");
replace=replace.replace(/\$/g,"$$$$");
}
if (options.indexOf("x")>=0) {
options=options.replace(/x/g,"");
replace=replace.replace(/\\\\/g,"\\B");
replace=replace.replace(/\\b/g,"\b");
replace=replace.replace(/\\f/g,"\f");
replace=replace.replace(/\\n/g,"\n");
replace=replace.replace(/\\r/g,"\r");
replace=replace.replace(/\\t/g,"\t");
replace=replace.replace(/\\v/g,"\v");
replace=replace.replace(/\\x[0-9a-fA-F]{2}|\\u[0-9a-fA-F]{4}/g,
function($0,$1,$2){
return String.fromCharCode(parseInt("0x"+$0.substring(2)));
}
);
replace=replace.replace(/\\B/g,"\\");
}
var search=new RegExp(search,options);
if (srcVar) {
WScript.Stdout.Write(env(args.Item(3)).replace(search,replace));
} else {
while (!WScript.StdIn.AtEndOfStream) {
if (multi) {
WScript.Stdout.Write(WScript.StdIn.ReadAll().replace(search,replace));
} else {
WScript.Stdout.WriteLine(WScript.StdIn.ReadLine().replace(search,replace));
}
}
}
감사합니다. dbenham ... 그게 도움이됩니다 .... – Bala
이미 매우 포괄적 인 (그리고 인상적인) Windows 고유 답변을 얻었습니다. 그래도 다른 유틸리티를 다운로드 할 수 있다면 http://gnuwin32.sourceforge.net/packages/sed.htm을 사용해보십시오. – lessthanideal