Excel, IF 문, vlookup - 너무 많은 매개 변수

올바른 방향으로 단순화하거나 안내 할 수 있습니까? 내 함수는 먼저 단어의 7 문자가 LABEL 테이블에 존재하는지 확인하고, 그렇지 않으면 6을 먼저 확인한 다음 5 등을 확인합니다. 이는 테이블에 CHARLYL 및 CHARLY을 포함 할 수 있기 때문입니다. 수식 아래에 넣을 때 "너무 많은 매개 변수"오류가 발생합니다. 나는 IF 진술에 한계가 있음을 깨닫지 못했다. 같은 것을하기위한 단순화 된 대체 방법이 있는가?Excel, IF 문, vlookup - 너무 많은 매개 변수

=if(isna(VLOOKUP(LEFT(A2,7),LABEL!A:B,2,0)), 
     if(isna(VLOOKUP(LEFT(A2,6),LABEL!A:B,2,0)), 
      if(isna(VLOOKUP(LEFT(A2,5),LABEL!A:B,2,0)), 
       if(isna(VLOOKUP(LEFT(A2,4),LABEL!A:B,2,0)), 
        if(isna(VLOOKUP(LEFT(A2,3),LABEL!A:B,2,0)), 
        "MISC",VLOOKUP(LEFT(A2,3),LABEL!A:B,2,0)), 
       "MISC",VLOOKUP(LEFT(A2,4),LABEL!A:B,2,0)), 
      "MISC",VLOOKUP(LEFT(A2,5),LABEL!A:B,2,0)), 
     "MISC",VLOOKUP(LEFT(A2,6),LABEL!A:B,2,0)), 
    "MISC",VLOOKUP(LEFT(A2,7),LABEL!A:B,2,0))

출처

2015-01-06 Elen

어떤 Excel 버전을 실행하고 있으며 2007 이전 버전과의 호환성을 제공해야합니까? XL2007로 인스톨 된 [IFERROR 함수] (https://support.office.com/en-US/Article/IFERROR-function-f59bacdc-78bd-4924-91df-a869d0b08cd5)는 중첩 된'IF (ISNA()) '수식. – Jeeped

조회 테이블 (CHA, CHAR, CHARL, CHARLY, CHARLYL 포함)은 수식을 단축 할 수 있습니다. – pnuts

@Jeeped 예 Excel 2007입니다. 감사합니다. – Elen

중첩 IFERROR 함수는 크게 IF(ISNA(...), ...) 당량에 비해 화학식을 감소시킬 수있다.

=IFERROR(VLOOKUP(LEFT(A2,7),LABEL!A:B,2,0), 
    IFERROR(VLOOKUP(LEFT(A2,6),LABEL!A:B,2,0), 
    IFERROR(VLOOKUP(LEFT(A2,5),LABEL!A:B,2,0), 
    IFERROR(VLOOKUP(LEFT(A2,4),LABEL!A:B,2,0), 
    IFERROR(VLOOKUP(LEFT(A2,3),LABEL!A:B,2,0), 
     "MISC")))))

다음은 수리 된 버전입니다. 기본값 인 MISC 매개 변수를 필요한 것보다 더 많이 추가하고있었습니다.

=IF(ISNA(VLOOKUP(LEFT(A2,7),LABEL!A:B,2,0)), 
     IF(ISNA(VLOOKUP(LEFT(A2,6),LABEL!A:B,2,0)), 
      IF(ISNA(VLOOKUP(LEFT(A2,5),LABEL!A:B,2,0)), 
       IF(ISNA(VLOOKUP(LEFT(A2,4),LABEL!A:B,2,0)), 
        IF(ISNA(VLOOKUP(LEFT(A2,3),LABEL!A:B,2,0)), 
        "MISC", 
        VLOOKUP(LEFT(A2,3),LABEL!A:B,2,0)), 
       VLOOKUP(LEFT(A2,4),LABEL!A:B,2,0)), 
      VLOOKUP(LEFT(A2,5),LABEL!A:B,2,0)), 
     VLOOKUP(LEFT(A2,6),LABEL!A:B,2,0)), 
    VLOOKUP(LEFT(A2,7),LABEL!A:B,2,0))

출처

2015-01-06 18:05:29 Jeeped

이것은 실제로 작동하는 것처럼 보입니다! (오, 그래 IF에 대해 - 예고하지 않았다) – Elen

Excel, IF 문, vlookup - 너무 많은 매개 변수

답변

관련 문제