Delphi - 스마트 포인터 생성자로 이상한 동작이 발생했습니다.

Question

여러 패키지가 포함 된 프로젝트에서 작업하고 있습니다. 그 (여기가 전체 코드입니다)처럼 내 기본 패키지 중 하나에서 나는, 스마트 포인터를 선언

나중에 내 프로젝트에

unit UTWSmartPointer; 

interface 

type 
    IWSmartPointer<T> = reference to function: T; 

    TWSmartPointer<T: class, constructor> = class(TInterfacedObject, IWSmartPointer<T>) 
    private 
     m_pInstance: T; 

    public 
     constructor Create; overload; virtual; 

     constructor Create(pInstance: T); overload; virtual; 

     destructor Destroy; override; 

     function Invoke: T; virtual; 
    end; 

implementation 
//--------------------------------------------------------------------------- 
constructor TWSmartPointer<T>.Create; 
begin 
    inherited Create; 

    m_pInstance := T.Create; 
end; 
//--------------------------------------------------------------------------- 
constructor TWSmartPointer<T>.Create(pInstance: T); 
begin 
    inherited Create; 

    m_pInstance := pInstance; 
end; 
//--------------------------------------------------------------------------- 
destructor TWSmartPointer<T>.Destroy; 
begin 
    m_pInstance.Free; 
    m_pInstance := nil; 

    inherited Destroy; 
end; 
//--------------------------------------------------------------------------- 
function TWSmartPointer<T>.Invoke: T; 
begin 
    Result := m_pInstance; 
end; 
//--------------------------------------------------------------------------- 

end. 

(다른 패키지), 나는 GDI + 개체 (함께이 스마트 포인터를 사용 TGpGraphicsPath). 다음과 같은 그래픽 경로를 선언합니다.

... 
pGraphicsPath: IWSmartPointer<TGpGraphicsPath>; 
... 
pGraphicsPath := TWSmartPointer<TGpGraphicsPath>.Create(); 
... 

그러나 코드를 실행할 때 화면에 아무 것도 그려지지 않습니다. 나는 오류도 예외도 액세스 위반도 없으며 단지 빈 페이지 만 얻는다. 하지만 난 그냥 그런 코드를 변경하는 경우 :

... 
pGraphicsPath: IWSmartPointer<TGpGraphicsPath>; 
... 
pGraphicsPath := TWSmartPointer<TGpGraphicsPath>.Create(TGpGraphicsPath.Create); 
... 

은 모두가 잘되고, 예상대로 내 경로가 정확하게 그려집니다. 하지만 첫 번째 생성자가 예상대로 작동하지 않는 이유를 알 수 없습니다. 누군가 나에게이 이상한 행동을 설명 할 수 있니?

감사합니다.

Answer 1

이것은 매우 복잡한 함정입니다. 당신이 쓸 때 :

TGpGraphicsPath.Create 

당신은 매개 변수없는 생성자를 호출하고 있다고 생각할 수 있습니다. 그러나 그렇지 않습니다. 실제로이 생성자를 호출하고 있습니다.

constructor Create(fillMode: TFillMode = FillModeAlternate); reintroduce; overload;  

기본값을 제공하므로 컴파일러에서 기본값을 제공합니다. 스마트 포인터 클래스에서

당신은 쓰기 :

T.Create 

이 정말 매개 변수가없는 생성자를 호출한다. 하지만 그것은 TObject에 의해 정의 된 생성자입니다. 해당 생성자를 사용하면 TGPGraphicsPath 인스턴스가 제대로 초기화되지 않습니다.

constructor 제네릭 제약 조건을 사용하려는 경우 매개 변수없는 생성자로 올바르게 구성 할 수있는 클래스를 항상 사용해야합니다. 불행히도 TGPGraphicsPath은 청구서에 맞지 않습니다. 실제로 그러한 수업은 우세합니다.

명시 적으로 생성자를 호출하지 않으려면 여기에서 할 수있는 일이 많지 않습니다. 스마트 포인터 클래스가이 특정 클래스에 대해 호출 할 생성자를 찾아내는 것은 거의 불가능합니다.

제 조언은 constructor 제네릭 제약에서 벗어나 스마트 포인터 클래스의 소비자가 명시 적으로 인스턴스를 인스턴스화하도록하는 것입니다.

이

꽤 일반적인 문제입니다 - 내가 적은보다는 일주일 전에 여기에 비슷한 질문에 대답 : Why does a deserialized TDictionary not work correctly?