파일 이름이있는 이름에 날짜가있는 .xml 파일을 .txt 파일로 나열하는 일괄 스크립트

Question

사전 도움을 주셔서 감사합니다.

폴더의 파일 이름에 날짜가있는 xml 파일이 있습니다.

예

• 프로필 - 20131126-1.xml
• 프로필 - 20131125-2.xml
• 프로필 - 20131124-5.xml
• Logic145242013_11_26.xml
• Logic154752013_11_25.xml
• 로직 154852013_11_24.xml

이제 26-11-2013 일 이하의 파일 이름을 .txt 파일로 가져와야합니다. 날짜는 파일 이름에서 볼 수 있습니다.

그래서 출력은 아래와 같아야합니다.

• 프로필 - 20131125-2.xml는
• 프로필 - 20131124-5.xml
• Logic154752013_11_25.xml
• Logic154852013_11_24.xml
는

어떤 하나 배치를 위해 좀 도와 주실 래요 스크립트.

감사와 안부, 시바

Answer 1

나는이 개 부분에서 문제를 분할보다 여기에 다른 해결책을 볼 수 없습니다 : 프로필에 대한 - * xml 파일 및 로직 * .XML 것들에 대한합니다..

아래 스크립트에서 20131126과 비교하여 이전 파일을 가져 왔습니다. 비교할 수 있도록 위의 형식으로 날짜를 얻기 위해 부분적으로 파일 이름을 분할하십시오.

@echo off 
setlocal EnableDelayedExpansion 

set mydate=20131126 

rem take each file name 
for %%a in (Profile-*-*.xml) do (
    rem take only data, split by dash and take second value 
    for /F "tokens=2 delims=-" %%f in ("%%a") do (
     rem compare with 20131126 
     if %%f LSS %mydate% ( 
      echo %%a>>txtfile.txt 
      rem Add processing of your files here 
     ) 
    ) 
) 

rem take each file name 
for %%a in (Logic*_*_*.xml) do (  
    rem put the value in a local parameter 
    set filename=%%a 
    rem take only the last 14 to 4 letters 
    set filename=!filename:~-14,-4! 
    rem remove underscores 
    set filename=!filename:_=! 
    rem compare with 20131126 
    if !filename! LSS %mydate% (   
     echo %%a>>txtfile.txt 
     rem Add processing of your files here 
    ) 
)