Perl 정규 표현식의 캡처를 별도의 변수에 저장하려면 어떻게해야합니까?

Question

저는 정규식을 가지고 있습니다 :

/abc(def)ghi(jkl)mno(pqr)/igs 

각 괄호의 결과를 각 괄호에 하나씩 3 개의 다른 변수로 어떻게 포착 할 수 있습니까? 지금은 하나의 배열을 사용하여 모든 결과를 캡처하지만 순차적으로 나옵니다. 그런 다음 구문 분석을해야하며 목록이 커질 수 있습니다.

@results = ($string =~ /abc(def)ghi(jkl)mno(pqr)/igs); 

Answer 1

귀하의 질문은 나에게 조금 모호하지만, 나는 당신이 이런 식으로 뭔가를하고 싶은 생각 :

my (@first, @second, @third); 
while(my ($first, $second, $third) = $string =~ /abc(def)ghi(jkl)mno(pqr)/igs) { 
    push @first, $first; 
    push @second, $second; 
    push @third, $third; 
} 

Answer 2

당신은 세 가지 다른 정규식의 각 특정 그룹에 초점을 맞추고있을 수 있습니다. 분명히, 당신은 정규식에있는 다른 배열에 다른 그룹을 할당하고 싶습니다,하지만 당신의 유일한 옵션은 정규 표현식을 분할하는 것입니다 생각합니다. 괄호를 캡처 할 때

Answer 3

@OP, 당신은 변수를 $ 1, $ 2 .... 이러한 역 참조

$string="zzzabcdefghijklmnopqrsssszzzabcdefghijklmnopqrssss"; 
while ($string =~ /abc(def)ghi(jkl)mno(pqr)/isg) { 
    print "$1 $2 $3\n"; 
} 

출력

$ perl perl.pl 
def jkl pqr 
def jkl pqr 

Answer 4

이 보일 것이다 일을하는 또 다른 방법을 사용할 수 있습니다 ghostdog74의 답변과 같지만 해시 참조를 저장하는 배열을 사용하는 경우 :

my @results; 
while($string =~ /abc(def)ghi(jkl)mno(pqr)/igs) { 
    my ($key1, $key2, $key3) = ($1, $2, $3); 
    push @results, { 
     key1 => $key1, 
     key2 => $key2, 
     key3 => $key3, 
    }; 
} 

# do something with it 

foreach my $result (@results) { 
    print "$result->{key1}, $result->{key2}, $result->{key3}\n"; 
} 

여기에 단일 데이터 구조를 사용하고 멋진 읽기 가능 루프가 있습니다.

Answer 5

5.10을 시작으로, 당신은뿐만 아니라 named capture buffers를 사용할 수 있습니다

이

#!/usr/bin/perl 

use strict; use warnings; 

my %data; 

my $s = 'abcdefghijklmnopqr'; 

if ($s =~ /abc (?<first>def) ghi (?<second>jkl) mno (?<third>pqr)/x) { 
    push @{ $data{$_} }, $+{$_} for keys %+; 
} 

use Data::Dumper; 
print Dumper \%data; 

출력 :

$VAR1 = { 
      'first' => [ 
         'def' 
        ], 
      'second' => [ 
         'jkl' 
         ], 
      'third' => [ 
         'pqr' 
        ] 
     };

이전 버전의 경우, 각 촬영을 위해 줄을 추가하는 것을 피한다 다음을 사용할 수 있습니다 버퍼 :

#!/usr/bin/perl 

use strict; use warnings; 

my $s = 'abcdefghijklmnopqr'; 

my @arrays = \ my(@first, @second, @third); 

if (my @captured = $s =~ /abc (def) ghi (jkl) mno (pqr) /x) { 
    push @{ $arrays[$_] }, $captured[$_] for 0 .. $#arrays; 
} 

use Data::Dumper; 
print Dumper @arrays; 

출력 :

$VAR1 = [ 
      'def' 
     ]; 
$VAR2 = [ 
      'jkl' 
     ]; 
$VAR3 = [ 
      'pqr' 
     ];

하지만 관련 데이터를 단일 데이터 구조로 유지하는 것이 좋으므로 해시를 사용하는 것이 가장 좋습니다. 변수의 이름이 정말 버퍼의 이름은 중요하지 않을 경우 first이 second는 등, 또는 만 위해, 당신은 사용할 수 않는 경우,

my %data; 
my @keys = qw(first second third); 

if (my @captured = $s =~ /abc (def) ghi (jkl) mno (pqr) /x) { 
    push @{ $data{$keys[$_]} }, $captured[$_] for 0 .. $#keys; 
} 

을 또는이 그러나, 보조 배열을 필요로하지 않습니다 :

my @data; 
if (my @captured = $s =~ /abc (def) ghi (jkl) mno (pqr) /x) { 
    push @{ $data[$_] }, $captured[$_] for 0 .. $#captured; 
}