VBScript의 목록

Question

VBscript에서 간단한 목록을 만들려고하지만 비슷한 것을 찾을 수 없습니다.

기본적으로 저는 Active Directory에서 작업 중이며 도메인 내의 모든 사용자에 대해 사용자가 속한 모든 그룹을 가져와야합니다. 이제는 모든 사용자가 다른 그룹 수의 구성원이 될 수 있으므로 사전에 키를 SAMID로 사용하고 가치는 사용자가 속한 모든 그룹의 목록으로 사용하려고합니다. .

정적 배열을 사용하여이 작업을 수행 할 수 있지만 그다지 좋지 않은 배열의 임의 크기가 크다는 것을 선언해야합니다. 내가 이상적으로하고 싶은 것은 python과 같은 목록을 가지고 있습니다. myList와 같은 일을 간단하게 할 수 있습니다. 추가하고 크기 조정에 대해 걱정할 필요가 없습니다.

나는 System.Collection.ArrayList를 사용하여 시도,하지만 난 그것을 실행할 때 오류가 발생합니다 :

PS C:\tmp> cscript.exe .\foo.vbs 
Microsoft (R) Windows Script Host Version 5.8 
Copyright (C) Microsoft Corporation. All rights reserved. 

C:\tmp\foo.vbs(1, 1) (null): 0x80131700 

가 어떻게 이러한 목표를 달성 할 수 있습니까?

Answer 1

Set dic = CreateObject("Scripting.Dictionary") 

dic.Add "Item1", "" 
dic.Add "Item2", "" 
dic.Add "Item3", "" 

Answer 2

사전을 없애고 ArrayList의 성능을 최대한 발휘하십시오.

Option Explicit 

dim list 
Set list = CreateObject("System.Collections.ArrayList") 
list.Add "Banana" 
list.Add "Apple" 
list.Add "Pear" 

list.Sort 
list.Reverse 

wscript.echo list.Count     ' --> 3 
wscript.echo list.Item(0)    ' --> Pear 
wscript.echo list.IndexOf("Apple", 0) ' --> 2 
wscript.echo join(list.ToArray(), ", ") ' --> Pear, Banana, Apple 

편집 : 난 당신이 이미 ArrayList를 시도했지만 오류가있어 참조하십시오. dotnet 프레임 워크의 설치가 올바르지 않은 것으로 보입니다 (System.Collections.ArrayList가 해당 부분입니다). Microsoft는 그 문제를 해결하는 방법에 대한 기사를 가지고 있습니다. http://answers.microsoft.com/en-us/windows/forum/windows_7-performance/error-code-0x80131700/3add8d80-00e0-4355-a994-8630d01c18f5

Answer 3

다음은 대안입니다 ... 내가 전에 만든 실제 List 클래스. 필요에 따라 자유롭게 사용하거나 수정할 수 있습니다. 내가 만든 원래 클래스는 ArrayIterator이라는 또 다른 사용자 정의 클래스에 따라 달라집니다.

Class List 
    Private mArray 

    Private Sub Class_Initialize() 
    mArray = Empty 
    End Sub 

    ' Appends the specified element to the end of this list. 
    Public Sub Add(element) 
    If IsEmpty(mArray) Then 
     ReDim mArray(0) 
     mArray(0) = element 
    Else 
     If mArray(UBound(mArray)) <> Empty Then 
     ReDim Preserve mArray(UBound(mArray)+1)   
     End If 
     mArray(UBound(mArray)) = element 
    End If 
    End Sub 

    ' Removes the element at the specified position in this list. 
    Public Sub Remove(index) 
    ReDim newArray(0) 
    For Each atom In mArray 
     If atom <> mArray(index) Then 
     If newArray(UBound(newArray)) <> Empty Then 
      ReDim Preserve newArray(UBound(newArray)+1) 
     End If 
     newArray(UBound(newArray)) = atom 
     End If 
    Next 
    mArray = newArray 
    End Sub 

    ' Returns the number of elements in this list. 
    Public Function Size 
    Size = UBound(mArray)+1 
    End Function 

    ' Returns the element at the specified position in this list. 
    Public Function GetItem(index) 
    GetItem = mArray(index) 
    End Function 

    ' Removes all of the elements from this list. 
    Public Sub Clear 
    mArray = Empty 
    End Sub 

    ' Returns true if this list contains elements. 
    Public Function HasElements 
    HasElements = Not IsEmpty(mArray) 
    End Function 

    Public Function GetIterator 
    Set iterator = New ArrayIterator 
    iterator.SetArray = mArray 
    GetIterator = iterator 
    End Function 

    Public Function GetArray 
    GetArray = mArray 
    End Function 

End Class 

소스 코드 클래스 ArrayIterator 에 대한 : 여기

는

Set myList = New List 
myList.Add("a") 
myList.Add("b") 
myList.Add("c") 

' Iterate through the List using ArrayIterator. You can of course use other methods... 
Set myListItr = myList.GetIterator 
While myListItr.HasNext 
    MsgBox myListItr.GetNext 
Wend 

' Iterate through the List by getting the underlying Array. 
Dim element 
For Each element In myList.GetArray 
    MsgBox element 
Next 

소스 코드 클래스 목록 을 위해 ... 그것을 사용하는 방법입니다

Class ArrayIterator 
    Private mArray 
    Private mCursor 

    Private Sub Class_Initialize() 
    mCursor = 0 
    End Sub 

    Public Property Let SetArray(array) 
    mArray = array  
    End Property 

    Public Function HasNext 
    HasNext = (mCursor < UBound(mArray)+1) 
    End Function 

    Public Function GetNext 
    GetNext = mArray(mCursor) 
    mCursor = mCursor + 1 
    End Function 
End Class