텍스트 마커를 열 텍스트로 바꿉니다.

Question

텍스트가있는 여러 열이 있습니다. 또한 Replacement text이라는 열이 있습니다. 이 열에는 마커가 포함 된 문자열이 들어 있습니다. 예 : [1], [2], etc.

마커를 마커 행에있는 텍스트로 바꾸고 싶습니다. [5]는 컬럼 마커이고 b 스트링의 행의 마커 값이기 때문에 예를 들면

는 Here you can find [5]는 Here you can find b된다.

큰 if-else 구조를 만들려고했는데 매우 오류가 발생하기 쉬운 substitute 텍스트를 생각했습니다.

그러나보다 쉬운 해결책이 있는지 궁금한 점이 있습니까?

입력 해 주셔서 감사합니다.

Answer 1

ReplaceBrackets1 : RegEx를 사용하여 열 번호를 추출합니다. 처리 된 100,000 개의 레코드에는 15.03 초가 소요됩니다.

---

Sub ReplaceBrackets1() 
    'http://analystcave.com/excel-regex-tutorial/ 
    Dim c As Range 
    Dim Match As Object, Matches As Object, regex As Object 
    Set regex = CreateObject("VBScript.RegExp") 

    With regex 
     .Global = True 
     .Pattern = "\[(.*?)\]" 
    End With 

    For Each c In Range("K3", Range("K" & Rows.Count).End(xlUp)) 
     If regex.Test(c.Text) Then 
      Set Matches = regex.Execute(c.Text) 
      For Each Match In Matches 
       c.Replace Match, c.EntireRow.Columns(CInt(Match.SubMatches(0))) 
      Next Match 

     End If 
    Next 
End Sub 

ReplaceBrackets2 : 배열로 loades 데이터는 열 번호를 추출 정규식을 사용하며 단지 워크에 1 회 기록한다. 100,000 레코드를 처리하는 데 1.27 초가 걸립니다.

---

Sub ReplaceBrackets2() 
'http://analystcave.com/excel-regex-tutorial/ 
    Dim x As Long, column As Long 
    Dim arData, values 
    Dim Match As Object, Matches As Object, regex As Object 
    Set regex = CreateObject("VBScript.RegExp") 

    With regex 
     .Global = True 
     .Pattern = "\[(.*?)\]" 
    End With 

    values = Range("K3", Range("K" & Rows.Count).End(xlUp)) 
    arData = Range("A3", "L" & UBound(values, 1) + 2) 

    For x = 1 To UBound(values, 1) 
     If regex.Test(values(x, 1)) Then 
      Set Matches = regex.Execute(values(x, 1)) 
      For Each Match In Matches 
       column = Match.SubMatches(0) 
       values(x, 1) = arData(x, column) 
      Next Match 
     End If 
    Next 

    Range("K3", Range("K" & Rows.Count).End(xlUp)) = values 

End Sub 

UDF ( getReplacedText)에 ReplaceBrackets1를 변환 한 후 나는 단지 100K 레코드에 대한 수식을 채우기 위해 2.53 초 걸렸 찾을 놀랐다. 이 방법이 원본보다 빠를 방법이 확실치 않습니다. 그러나 많은 수식을 사용하면 실제로 스프레드 시트가 느려집니다.

getReplacedText : 정적 RegEx를 사용하여 데이터를 구문 분석합니다.

Function getReplacedText(ReplacementText As String, Source As Range) 
'http://analystcave.com/excel-regex-tutorial/ 
    Dim Match As Object, Matches As Object 
    Static regex As Object 
    If regex Is Nothing Then 
     Set regex = CreateObject("VBScript.RegExp") 

     With regex 
      .Global = True 
      .Pattern = "\[(.*?)\]" 
     End With 
    End If 

    If regex.Test(ReplacementText) Then 
     Set Matches = regex.Execute(ReplacementText) 
     For Each Match In Matches 
      ReplacementText = Replace(ReplacementText, Match, Source.Columns(CInt(Match.SubMatches(0)))) 
     Next Match 

    End If 

    getReplacedText = ReplacementText 
End Function 

Answer 2

이 답변은 매우 그의 대답의 토마스 Inzina의 첫 번째 버전에서 표절되지만 교체를 수행하는 매우 간단한 방법은 다음과 같습니다

Sub ReplaceText() 
    Dim r As Long 
    Dim c As Long 
    With ActiveSheet 
     For r = 3 To .Range("K" & .Rows.Count).End(xlUp).Row 
      For c = 1 To 10 
       .Cells(r, "K").Replace "[" & c & "]", .Cells(r, c).Value 
      Next 
     Next 
    End With 
End Sub 

위의 코드를 사용하여 치환을하려고합니다 모두 열두 열.

토마스가 언급했듯이있는 교체를 빨리 크기 순서가 될 수 있으므로 필요하며, 경우, 다음 코드는 그래서 더 나은 솔루션 의심 할 여지없이, 대체 할 만합니다

Sub ReplaceText() 
    Dim r As Long 
    Dim c As Long 
    With ActiveSheet 
     For r = 3 To .Range("K" & .Rows.Count).End(xlUp).Row 
      For c = 1 To 10 
       If Instr(.Cells(r, "K").Value, "[" & c & "]") > 0 Then 
        .Cells(r, "K").Replace "[" & c & "]", .Cells(r, c).Value 
       End If 
      Next 
     Next 
    End With 
End Sub 

(많은 감사에가 Thomas는 두 가지 다른 방법으로 속도 테스트를 수행하기 위해 노력했습니다.)