차트를 이미지로 내보내기 - 버튼 클릭 포함

Question

"Graphs"시트의 차트를 jpeg 파일로 내보내는 버튼을 만들려고합니다. 이것은 내가 가지고있는 코드입니다, 그러나 그것은이 오류를 보여주는 유지 :이 특별히

runtime error 424: object required

:

Set myChart = Graphs.ChartObjects(3).Name = "Chart4" 

을 그리고 여기에 코드

Sub ExportChart() 
    Dim myChart As Chart 
    Dim myFileName As String 
    Set myChart = Graphs.ChartObjects(3).Name = "Chart4" 
    myFileName = "myChart.jpg" 
    On Error Resume Next 
    Kill ThisWorkbook.Path & "\" & myFileName 
    myChart.Export Filename:=ThisWorkbook.Path & "\" & myFileName, Filtername:="PNG" 
    MsgBox "OK" 
    Set myChart = Nothing 
End Sub 

모두에게 감사입니다!

Answer 1

이게 너가하려는거야?

또한 jpg로 저장하려는 경우 왜 png 필터가 필요합니까? "myChart.jpg"를 "myChart.png"로 변경했습니다. 해당되는 경우 변경하십시오.

Sub ExportChart() 
    Dim objChrt As ChartObject 
    Dim myChart As Chart 

    Set objChrt = Sheets("Graphs").ChartObjects(3) 
    Set myChart = objChrt.Chart 

    myFileName = "myChart.png" 

    On Error Resume Next 
    Kill ThisWorkbook.Path & "\" & myFileName 
    On Error GoTo 0 

    myChart.Export Filename:=ThisWorkbook.Path & "\" & myFileName, Filtername:="PNG" 

    MsgBox "OK" 
End Sub 

Answer 2

감사합니다. 이미지의 모든 차트를 추출해야하며 거의 자정입니다. 위의 코드를 약간 변경하면 트릭을 만들 수 있습니다.

Sub ExportChart() 
    Dim WS As Excel.Worksheet 
    Dim SaveToDirectory As String 

    Dim objChrt As ChartObject 
    Dim myChart As Chart 

    SaveToDirectory = ActiveWorkbook.Path & "\" 

    For Each WS In ActiveWorkbook.Worksheets 
     WS.Activate 'go there 
     For Each objChrt In WS.ChartObjects 
      objChrt.Activate 
      Set myChart = objChrt.Chart 

      myFileName = SaveToDirectory & WS.Name & "_" & objChrt.Index & ".png" 

      On Error Resume Next 
      Kill SaveToDirectory & WS.Name & Index & ".png" 
      On Error GoTo 0 

      myChart.Export Filename:=myFileName, Filtername:="PNG" 
     Next 
    Next 

    MsgBox "OK" 
End Sub