XSLT : XML 요소 분할 및 병합

Question

저는 XSLT 프로그래밍의 초보자입니다.

<Test>TestA::test1</Test> 
<Test>TestA::test2</Test> 
<Test>TestB::test3</Test> 
<Test>TestB::test4</Test> 

출력 XML은 다음과 같이한다 : 나는 다음과 같은 XML 변환하는 작업이있어 ​​

<Class id="TestA"> 
    <Method id="test1"/> 
    <Method id="test2"/> 
</Class> 
<Class id="TestB"> 
    <Method id="test3"/> 
    <Method id="test4"/> 
</Class> 

입력 XML은 C++ 스타일 CppUnit을 테스트 케이스의 이름을 포함를 (패턴 클래스 ::방법). 많은 접근법을 시도하고 무수히 많은 stackoverflow threds를 읽었지만 해결책을 찾지 못했습니다.

XSLT 1.0을 사용하여이 문제를 해결해야합니다. 사전에

감사합니다, mexl

이 기본적으로 그룹화 문제, A (아주 약간) 트위스트와 함께 Muenchian grouping에 의해 (XSLT 1.0) 해결 될 것입니다

Answer 1

. 그러나 먼저 입력은 루트 요소가 있어야합니다 - 그렇지 않으면 XML 문서 아니다 : 장소에두고

<root> 
    <Test>TestA::test1</Test> 
    <Test>TestA::test2</Test> 
    <Test>TestB::test3</Test> 
    <Test>TestB::test4</Test> 
</root> 

, 다음 스타일 시트 :

XSLT 1.0

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 

<xsl:key name="k" match="Test" use="substring-before(., '::')" /> 

<xsl:template match="/"> 
    <output> 
     <xsl:for-each select="root/Test[count(. | key('k', substring-before(., '::'))[1]) = 1]"> 
      <Class id="{substring-before(., '::')}"> 
       <xsl:for-each select="key('k', substring-before(., '::'))"> 
        <Method id="{substring-after(., '::')}"/> 
       </xsl:for-each> 
      </Class> 
     </xsl:for-each> 
    </output> 
</xsl:template> 

</xsl:stylesheet> 

것 반환 :

<?xml version="1.0" encoding="UTF-8"?> 
<output> 
    <Class id="TestA"> 
     <Method id="test1"/> 
     <Method id="test2"/> 
    </Class> 
    <Class id="TestB"> 
     <Method id="test3"/> 
     <Method id="test4"/> 
    </Class> 
</output> 

Answer 2

xsl:key/generate-id는 substring-before /substring-after는,로는 다음과 같습니다

이

<Tests> 
    <Test>TestA::test1</Test> 
    <Test>TestA::test2</Test> 
    <Test>TestB::test3</Test> 
    <Test>TestB::test4</Test> 
</Tests> 

을 주어 사용이 템플릿 :

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

<xsl:output indent="yes" method="xml" encoding="UTF-8"/> 

<xsl:key name="testClassKey" match="Test" use="substring-before(., '::')"/> 

<xsl:template match="Test" mode="asMethod"> 
    <xsl:variable name="methodId" select="substring-after(., '::')" /> 

    <Method id="{$methodId}" /> 
</xsl:template> 


<xsl:template match="Test"> 
    <xsl:variable name="thisTest" select="." /> 
    <xsl:variable name="classId" select="substring-before(., '::')" /> 

    <Class id="{$classId}"> 
    <xsl:apply-templates select="//Test[substring-before(., '::') = $classId]" mode="asMethod"/> 
    </Class> 
</xsl:template> 


<xsl:template match="Tests"> 
    <TestClasses> 
    <xsl:apply-templates select="Test[generate-id(.) = generate-id(key('testClassKey', substring-before(., '::'))[1])]" /> 
    </TestClasses> 
</xsl:template> 
</xsl:stylesheet> 

이 결과를 얻으려면 :

<?xml version="1.0" encoding="UTF-8"?> 
<TestClasses> 
    <Class id="TestA"> 
    <Method id="test1" /> 
    <Method id="test2" /> 
    </Class> 
    <Class id="TestB"> 
    <Method id="test3" /> 
    <Method id="test4" /> 
    </Class> 
</TestClasses>