간단한 플래시 AS2 코드를 AS3으로 변환

Question

나는 초보자이며 튜토리얼 : http://www.webwasp.co.uk/tutorials/018/tutorial.php ... "라이브 페인트/그리기"효과를 만드는 방법을 배우려면 .... AS2에서 무언가를 만들면, 루트 AS3 파일에이 파일을 임베드 (및 작동) 할 수 없다는 사실을 깨닫지 못했다. AS2 코드를 AS3으로 변경하는 방법에 대한 팁을 따르려고했으나 작동하지 않습니다. 나는 그것이 단순한 코드라는 것을 알고 있으며, 거기에있는 어떤 천재는 그것을 이해할 수 있지만, 나는 손실에 처해있다. 도와주세요! 여기

_root.createEmptyMovieClip("myLine", 0); 

_root.onMouseDown = function() { 
    myLine.moveTo(_xmouse, _ymouse); 
    ranWidth = Math.round((Math.random() * 10)+2); 
    myLine.lineStyle(ranWidth, 0xff0000, 100); 
    _root.onMouseMove = function() { 
     myLine.lineTo(_xmouse, _ymouse); 
    } 
} 

_root.onMouseUp = function() { 
    _root.onMouseMove = noLine; 
} 

Answer 1

을이 정말 문제가 아닙니다 AS3

import flash.display.Sprite; 
import flash.events.MouseEvent; 

var ranWidth:Number; 

//creation of a new clip (Sprite is the base class of MovieClip, 
//it's the same without the unneeded timeline) 
var myLine:Sprite = new Sprite(); 
addChild(myLine); 

//in AS3 the main container is stage, not _root 
//you see here the main difference between beginner AS3 and beginner AS2: 
//event listeners 
stage.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown); 


function onMouseDown(event:MouseEvent):void 
{ 
    myLine.graphics.moveTo(mouseX, mouseY); 
    ranWidth = Math.round((Math.random() * 10)+2); 
    myLine.graphics.lineStyle(ranWidth, 0xff0000, 100); 
    stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove); 
    stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUp); 
} 

//nesting function in other functions is not a good practice 
function onMouseMove(event:MouseEvent):void 
{ 
    myLine.graphics.lineTo(mouseX, mouseY); 
} 

function onMouseUp(event:MouseEvent):void 
{ 
    stage.removeEventListener(MouseEvent.MOUSE_MOVE, onMouseMove); 
    stage.removeEventListener(MouseEvent.MOUSE_UP, onMouseUp); 
}