델파이에 패치 루틴 호출

Question

일부 수정을 통해 직접 처리 할 수 ​​있도록 루틴 호출을 패치하고 싶습니다. 리소스 로더를 작성 중입니다. Delphi의 LoadResourceModule과 InitInheritedComponent 루틴을 내 패치로 패치하고 싶습니다. 내가 MadEcept.pas 단위에서 PatchAPI 호출을 확인했지만 내 프로젝트에 사용할 수 있다면 그것을 알아낼 수 없습니다. 이에

모든 포인터는 매우 도움이 될 것입니다 ...> MyCustomResourceModule -> LoadResourceModule - -> 점프에

나는 런타임 통화에서

내 EXE 같은 것을 원한다.

procedure PatchCode(Address: Pointer; const NewCode; Size: Integer); 
var 
    OldProtect: DWORD; 
begin 
    if VirtualProtect(Address, Size, PAGE_EXECUTE_READWRITE, OldProtect) then 
    begin 
    Move(NewCode, Address^, Size); 
    FlushInstructionCache(GetCurrentProcess, Address, Size); 
    VirtualProtect(Address, Size, OldProtect, @OldProtect); 
    end; 
end; 

type 
    PInstruction = ^TInstruction; 
    TInstruction = packed record 
    Opcode: Byte; 
    Offset: Integer; 
    end; 

procedure RedirectProcedure(OldAddress, NewAddress: Pointer); 
var 
    NewCode: TInstruction; 
begin 
    NewCode.Opcode := $E9;//jump relative 
    NewCode.Offset := NativeInt(NewAddress)-NativeInt(OldAddress)-SizeOf(NewCode); 
    PatchCode(OldAddress, NewCode, SizeOf(NewCode)); 
end; 

당신은 RedirectProcedure를 호출하여 후크/패치/우회를 구현하는 것이 :

RedirectProcedure(@LoadResourceModule, @MyLoadResourceModule); 

이 32 비트 코드를 작동

Answer 1

는 다음 코드를 사용합니다. 또한 이전 함수와 새 함수가 동일한 실행 모듈에있는 경우 64 비트 코드에서도 작동합니다. 그렇지 않으면 점프 거리가 32 비트 정수의 범위를 초과 할 수 있습니다.

두 사람의 주소가 얼마나 멀리 떨어져 있는지에 관계없이 누군가가 64 비트 주소 공간에서 근무하는 대안을 제공 할 수 있다면 매우 흥미 롭습니다.

Answer 2

이미 Delphi detours library이 있습니다.

델파이 본론 도서관

는 .IT 쉬운 삽입하는 방법과 제거 후크를 제공 델파이 및 Windows API 함수를 후크 할 수 있도록 라이브러리입니다.

특징 :

• 지원 x86 및 x64 아키텍처.
• 트램펄린 기능을 통해 원래 기능 호출 허용.
• 멀티 훅 지원.
• COM/인터페이스/win32api 지원.
• COM vtable 패치 지원.
• 완전 스레드 안전 코드 후킹 및 언 후킹.
• 지원 후킹 개체 메서드.
• 지원되는 Delphi 7/2005-2010/XE-XE7.
• 나사로/FPC를 지원합니다.
• 64 비트 주소가 지원됩니다.
• 라이브러리는 외부 라이브러리를 사용하지 않습니다.
• 라이브러리는 언제든지 후크를 삽입하고 제거 할 수 있습니다.
• 라이브러리에는 asm 명령어 (x86 & x64)를 디코딩 할 수있는 InstDecode 라이브러리가 들어 있습니다.

Answer 3

필자는 David Heffernan의 64 비트 지원 코드와 BPL의 메소드 간접 점프를 수정했습니다. 일부 도움으로 : http://chee-yang.blogspot.com.tr/2008/11/hack-into-delphi-class.html

type 
    PAbsoluteIndirectJmp = ^TAbsoluteIndirectJmp; 
    TAbsoluteIndirectJmp = packed record 
    OpCode: Word; // $FF25(Jmp, FF /4) 
    Addr: DWORD; // 32-bit address 
        // in 32-bit mode: it is a direct jmp address to target method 
        // in 64-bit mode: it is a relative pointer to a 64-bit address used to jmp to target method 
    end; 

    PInstruction = ^TInstruction; 
    TInstruction = packed record 
    Opcode: Byte; 
    Offset: Integer; 
    end; 


function GetActualAddr(Proc: Pointer): Pointer; 
begin 
    Result := Proc; 
    if Result <> nil then 
    if PAbsoluteIndirectJmp(Result)^.OpCode = $25FF then // we need to understand if it is proc entry or a jmp following an address 
{$ifdef CPUX64} 
     Result := PPointer(NativeInt(Result) + PAbsoluteIndirectJmp(Result)^.Addr + SizeOf(TAbsoluteIndirectJmp))^; 
     // in 64-bit mode target address is a 64-bit address (jmp qword ptr [32-bit relative address] FF 25 XX XX XX XX) 
     // The address is in a loaction pointed by (Addr + Current EIP = XX XX XX XX + EIP) 
     // We also need to add (instruction + operand) size (SizeOf(TAbsoluteIndirectJmp)) to calculate relative address 
     // XX XX XX XX + Current EIP + SizeOf(TAbsoluteIndirectJmp) 
{$else} 
     Result := PPointer(PAbsoluteIndirectJmp(Result)^.Addr)^; 
     // in 32-bit it is a direct address to method 
{$endif} 
end; 

procedure PatchCode(Address: Pointer; const NewCode; Size: Integer); 
var 
    OldProtect: DWORD; 
begin 
    if VirtualProtect(Address, Size, PAGE_EXECUTE_READWRITE, OldProtect) then //FM: remove the write protect on Code Segment 
    begin 
    Move(NewCode, Address^, Size); 
    FlushInstructionCache(GetCurrentProcess, Address, Size); 
    VirtualProtect(Address, Size, OldProtect, @OldProtect); // restore write protection 
    end; 
end; 

procedure RedirectProcedure(OldAddress, NewAddress: Pointer); 
var 
    NewCode: TInstruction; 
begin 
    OldAddress := GetActualAddr(OldAddress); 

    NewCode.Opcode := $E9;//jump relative 
    NewCode.Offset := NativeInt(NewAddress) - NativeInt(OldAddress) - SizeOf(NewCode); 

    PatchCode(OldAddress, NewCode, SizeOf(NewCode)); 
end;