롤오버 애니메이션을 위해 기본 ActionScript 2를 ActionScript 3로 변환

Question

그래서 내가하려는 것은 단순해야합니다. 사용자가 마우스를 굴릴 때 되돌리기 만하는 롤오버 애니메이션입니다. AS2에 있지만, 프로젝트를 끝내려면 AS3에서 필요하다고 생각합니다. 누구든지이 변환에 대한 조언을 드릴 수 있습니까?

stop(); 

this.onEnterFrame = function(){ 
if(rewind == true){ 
prevFrame(); 
} 
} 

this.onRollOver = function(){ 
rewind = false; 
play(); 
} 

this.onRollOut = function(){ 
rewind = true; 
} 

this.onRelease = function(){ 
getURL("http://www.google.com","_blank"); 
} 

...에 AS3? 나는 진심으로 감사 할 것입니다.

Answer 1

코드 요구 사항이 이들에 국한되어있는 경우 AS3에서 코드를 한 번만 수행하는 방법을 배워야합니다. 여기

AS3에서 똑같은 일이

import flash.events.Event; 
import flash.events.MouseEvent; 
import flash.net.navigateToURL; 
import flash.net.URLRequest; 

stop(); 
addEventListener(Event.ENTER_FRAME, onEnterFrame); 
addEventListener(MouseEvent.MOUSE_OVER, onMouseOver); 
addEventListener(MouseEvent.MOUSE_OUT, onMouseOut); 
addEventListener(MouseEvent.CLICK, onClick); 

var rewind:Boolean = false; 

function onEnterFrame(event:Event):void 
{ 
    if (rewind == true) { 
     prevFrame(); 
    } 
} 

function onMouseOver(event:MouseEvent):void 
{ 
    rewind = false; 
    play(); 
} 

function onMouseOut(event:MouseEvent):void 
{ 
    rewind = true; 
} 

function onClick(event:MouseEvent):void 
{ 
    navigateToURL(new URLRequest("http://www.google.com"),"_blank"); 
} 

는 this.onRollOver = function()를 작성하여 (예를 들어 이월) 대신 이벤트 리스너를 만드는 것을주의하십시오, 당신은 실제로 꽤 논리적 인 (addEventListener를 호출해야), 청취하려는 이벤트를 지정하고이 이벤트가 포착 될 때 호출되는 함수를 작성하십시오.

이 getURL의 또 다른 차이도 ->navigateToURL,하지만 나는 그것을 감사의로

을 :) 당신은 더 이상 설명이 필요없는 생각, 난 정말이 코드를 읽고 시도 감사하겠습니다 대략 복사/붙여 넣기 대신에 그것을 배우십시오. 하지만 이봐, 너는 자유 야!