Vlookup 매크로 2 워크 시트

Question

저는 VBA에 매우 익숙하며 도움을받을 수 있습니다. 나는 수동으로 셀에 입력하는 대신 vlookup을 수행하는 매크로를 만들려고합니다.

내 Excel 파일에는 'Microsoft'라는 워크 시트와 'SN 사용자 이름'이라는 두 개의 워크 시트가 있습니다.

그래서 나는 = VLOOKUP (시트 '마이크로 소프트 (B21) 여기

은 VBA에서 수행하려고 VLOOKUP 메신저 인에 B21를 반환하는 조회의 결과'SN 사용자 이름 '에서 데이터를 찾고 있어요 , 'SN 사용자 이름'! A : B, 2, FALSE)

감사의 말을 전합니다. 감사합니다.

Answer 1

VBA 버전 기능 Application.VLookup을 사용할 수 있습니다.

아래의 코드 코드는 시트 "Microsoft"의 셀 B21 값이 시트 "SN 사용자 이름"의 열 A : B에 있는지 확인합니다. 발견되면 셀 A21에 두 번째 열을 반환합니다 (필요에 따라 수정할 수 있음). 그렇지 않으면 참조 용으로 "Item Not Found"라는 텍스트 메시지를 A21 셀에 넣습니다.

Option Explicit 

Sub VLookup_withErrHandling() 

Dim Cell    As Range 
Dim Rng     As Range 
Dim lRow    As Range 

Set Cell = Sheets("Microsoft").Range("B21") 
Set Rng = Sheets("SN Username").Range("A:B") 

If Not IsError(Application.VLookup(Cell, Rng, 2, False)) Then 
    Cell.Offset(0, -1).Value = Application.VLookup(Cell, Rng, 2, False) 
Else 
    Cell.Offset(0, -1).Value = "Item Not Found" 
End If 

End Sub 

For 루프 추가 :

Dim lRow    As Long 

' just for example, loop from row 21 until row 30 
For lRow = 21 To 30 
    Set Cell = Sheets("Microsoft").Range("B" & lRow) 

    If Not IsError(Application.VLookup(Cell, Rng, 2, False)) Then 
     Cell.Offset(0, -1).Value = Application.VLookup(Cell, Rng, 2, False) 
    Else 
     Cell.Offset(0, -1).Value = "Item Not Found" 
    End If 

Next lRow 

편집 1 : 당신이 당신의 "마이크로 소프트"시트에서 많은 행을 반복 할 경우에, 당신은 아래의 코드 조각을 추가 할 수 있습니다 : 아래 수정 된 메모에 따라

Option Explicit 

Sub VLookup_withErrHandling() 

Dim Cell    As Range 
Dim Rng     As Range 
Dim LastRow    As Long 
Dim lRow    As Long 

With Sheets("SN Username") 
    ' find last row with username in column A 
    LastRow = .Cells(.Rows.Count, "A").End(xlUp).Row 

    Set Rng = Sheets("SN Username").Range("A2:B" & LastRow) 
End With 

' loop through row 2 until row 20 
For lRow = 2 To 20 
    Set Cell = Sheets("Microsoft").Range("A" & lRow) 

    If Not IsError(Application.VLookup(Cell.Value, Rng, 2, False)) Then 
     Cell.Offset(0, 1).Value = Application.VLookup(Cell.Value, Rng, 2, False) 
    Else 
     Cell.Offset(0, 1).Value = "UserName Not Found in SN UserNames sheet" 
    End If 

Next lRow 

End Sub