applescript를 사용하여 으르렁 알림을 넣는 방법은 무엇입니까?

Question

SVN의 작업 복사본을 업데이트하는 스크립트를 사용하고 있습니다.

으르렁 거림이 설치되었습니다. 내 스크립트가 SVN의 작업 복사본을 업데이트하고 나면 Growl 알림을 넣고 싶습니다.

도와주세요.

Answer 1

Google과 Growl의 사이트에서 조금만 검색하면 문제가 해결되었을 수 있습니다.

Click here.

또는 직접이 코드를 Apple 스크립트 편집기에 붙여넣고 작동 방법을 확인하십시오.

tell application "System Events" 
    set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0 
end tell 

if isRunning then 
    tell application id "com.Growl.GrowlHelperApp" 
     -- Make a list of all the notification types 
     -- that this script will ever send: 
     set the allNotificationsList to ¬ 
      {"Test Notification", "Another Test Notification"} 

     -- Make a list of the notifications 
     -- that will be enabled by default.  
     -- Those not enabled by default can be enabled later 
     -- in the 'Applications' tab of the Growl preferences. 
     set the enabledNotificationsList to ¬ 
      {"Test Notification"} 

     -- Register our script with growl. 
     -- You can optionally (as here) set a default icon 
     -- for this script's notifications. 
     register as application ¬ 
      "Growl AppleScript Sample" all notifications allNotificationsList ¬ 
      default notifications enabledNotificationsList ¬ 
      icon of application "Script Editor" 

     --  Send a Notification... 
     notify with name ¬ 
      "Test Notification" title ¬ 
      "Test Notification" description ¬ 
      "This is a test AppleScript notification." application name "Growl AppleScript Sample" 

     notify with name ¬ 
      "Another Test Notification" title ¬ 
      "Another Test Notification :) " description ¬ 
      "Alas — you won't see me until you enable me..." application name "Growl AppleScript Sample" 

    end tell 
end if 

이 질문이 해결 되었기를 바랍니다.

Answer 2

정말 스크립트에서 GrowlNotify (http://growl.info/extras.php#growlnotify)를 사용하는 것이 더 좋습니다. AppleScript를 통해 쉽고 직접적으로 확장 할 수 있습니다.