TextArea에서 Winword 및 메모장에 저장하는 데이터를 가져 오는 방법은 무엇입니까?

내 스크립팅 과제의 일부로, 사용자가 텍스트 영역에 데이터를 입력 할 수있는 html 양식을 만들어야합니다.이 양식은 : H 드라이브에 Word 또는 메모장 문서로 저장할 수 있습니다. HTA를 사용합니다. HTML 양식 부분은 매우 쉽지만 두 버튼 중 하나를 클릭하면 올바른 위치에 데이터가 저장되도록 작동하는 데 어려움을 겪고 있습니다. 지금까지 Word에서 파일을 저장하는 데 필요한 첫 번째 단추를 먼저 구하는 작업을 해왔지만 솔직히 여기서부터 어디로 가야할지를 놓치지 않았습니다. 지금까지 가지고있는 코드는 다음과 같습니다.TextArea에서 Winword 및 메모장에 저장하는 데이터를 가져 오는 방법은 무엇입니까?

<html> 
<head> 
<HTA:APPLICATION> 

<script type="text/javascript" language="javascript"> 
function SaveFile() 
{ 
wordApp = new ActiveXObject("Word.Application"); 
wordApp.Visible = true; 
} 
</script> 
</head> 
<body> 
<form> 
Enter your information: 
<br /> 
<textarea cols="40" rows="12"> 
</textarea> 
<br /> 
<input type="button" value="save into word" id="Word.Application" /> 
<input type="button" value="save into notepad" /> 
</form> 
</body> 
</html>

이 질문에 도움이 될만한 자료가 있습니까? 미리 감사드립니다.

출처

2017-09-23 Paraiyar

조치를 실행하는 이벤트가 없습니다. 이 경우 'onClick'. 따라서 'onClick'은 SaveFile 함수를 호출합니다. SaveFile 함수에 전달 된 값에 따라 데이터를 저장하는 데 사용되는 응용 프로그램이 무엇인지에 따라 일반 저장 함수를 사용하는 것이 좋습니다 (이 경우 조건부 구조 중 하나를 사용할 수 있음).

onClick="SaveFile('notepad')" //saves data in notepad 

onClick="SaveFile('word')" //saves data in word

출처

2017-09-23 04:25:08

당신이 HTA에 대한 시도 제공 할 수 있습니다 :

<html> 
<Title>Save file into noteapd and Word Application</Title> 
<META HTTP-EQUIV="MSThemeCompatible" CONTENT="YES"> 
<head> 
<HTA:APPLICATION 
ICON="Notepad.exe" 
APPLICATIONNAME = "Save file into noteapd and Word Application" 
BORDER="dialog" 
BORDERSTYLE="complex" 
> 
</head> 
<script type="text/Vbscript"> 
'***************************************************** 
Sub window_onload() 
    CenterWindow 500,350 
End Sub 
'***************************************************** 
Sub CenterWindow(x,y) 
    Dim iLeft,itop 
    window.resizeTo x,y 
    iLeft = window.screen.availWidth/2 - x/2 
    itop = window.screen.availHeight/2 - y/2 
    window.moveTo ileft,itop 
End Sub 
'***************************************************** 
Sub Save2Word() 
'Create and Save a Word Document 
Title = "Data saved into Word Appplication" 
FileDoc = "C:\" & Month(Date) & "_" & Day(Date) & "_" & Year(Date) & ".doc" 
Set objWord = CreateObject("Word.Application") 
objWord.Visible = False 
Txtarea = document.all("Txtarea").Value 
Set objDoc = objWord.Documents.Add() 
Set objSelection = objWord.Selection 
objSelection.Font.Name = "Comic Sans MS" 
objSelection.Font.Size = "12" 
objSelection.TypeText Txtarea 
objDoc.SaveAs(FileDoc) 
objWord.Quit 
MsgBox "Data saved into : " & FileDoc,vbInformation,Title 
End Sub 
'***************************************************** 
Sub Save2Notepad() 
'Save into a Notepad Document 
Title = "Data saved into Notepad Appplication" 
Set fso = CreateObject("Scripting.FileSystemObject") 
FileTxt = "C:\" & Month(Date) & "_" & Day(Date) & "_" & Year(Date) & ".txt" 
Txtarea = document.all("Txtarea").Value 
Set oFile = fso.OpenTextFile(FileTxt,8,true) 
oFIle.WriteLine Txtarea 
oFile.Close 
MsgBox "Data saved into : " & FileTxt,vbInformation,Title 
End Sub 
'***************************************************** 
</script> 
<body> 
<center> 
<form> 
Enter your information: 
<br> 
<textarea ID="Txtarea" NAME="Txtarea" cols="40" rows="12"></textarea> 
<hr> 
<input type="button" value="save into word" onClick="Save2Word()"/> 
<input type="button" value="save into notepad" onClick="Save2Notepad()"/> 
<hr> 
</form> 
</center> 
</body> 
</html>

을

출처

2017-09-25 11:07:23 Hackoo

TextArea에서 Winword 및 메모장에 저장하는 데이터를 가져 오는 방법은 무엇입니까?

답변

관련 문제