Perl : STDOUT을 두 파일로 리디렉션

Question

STDOUT 스트림을 Perl 스크립트 내에서 두 개의 파일 (중복)로 리디렉션 할 수 있습니까? 현재 단일 로그 파일로 스트리밍 중입니다 :

open(STDOUT, ">$out_file") or die "Can't open $out_file: $!\n"; 

무엇을 변경해야합니까? 고마워.

Answer 1

또한 IO::Tee을 사용할 수 있습니다.

use strict; 
use warnings; 
use IO::Tee; 

open(my $fh1,">","tee1") or die $!; 
open(my $fh2,">","tee2") or die $!; 

my $tee=IO::Tee->new($fh1,$fh2); 

select $tee; #This makes $tee the default handle. 

print "Hey!\n"; #Because of the select, you don't have to do print $tee "Hey!\n" 

는 그리고 네, 출력 작동 :

> cat tee1 
Hey! 
> cat tee2 
Hey! 

Answer 2

유닉스 계열 시스템을 사용하는 경우 tee 유틸리티를 사용하십시오.

$ perl -le 'print "Hello, world"' | tee /tmp/foo /tmp/bar 
Hello, world 

$ cat /tmp/foo /tmp/bar 
Hello, world 
Hello, world

는 외부 티 과정에 STDOUT에서 파이프를 설정, 프로그램 내에서이 복제를 설정합니다. "|-"을 open으로하면 쉽게 처리 할 수 ​​있습니다.

#! /usr/bin/env perl 

use strict; 
use warnings; 

my @copies = qw(/tmp/foo /tmp/bar); 

open STDOUT, "|-", "tee", @copies or die "$0: tee failed: $!"; 

print "Hello, world!\n"; 

close STDOUT or warn "$0: close: $!"; 

데모 :

$ ./stdout-copies-demo 
Hello, world! 

$ cat /tmp/foo /tmp/bar 
Hello, world! 
Hello, world!

Answer 3

File::Tee는 당신이 필요로하는 기능을 제공합니다.

use File::Tee qw(tee); 
tee(STDOUT, '>', 'stdout.txt'); 

Answer 4

PerlIO 레이어를 사용하십시오.

use PerlIO::Util; 
*STDOUT->push_layer(tee => "/tmp/bar"); 
print "data\n"; 

$ perl tee_script.pl > /tmp/foo 
$ cat /tmp/foo 
data 
$ cat /tmp/bar 
data