각 열 평균의 셀 값 비교

Question

Excel 용 vba 코드를 준비하려고합니다. 매달 값의 목록이 있으며 매달 별도의 열에 나열되며 매월 아래에 여러 값이 나열됩니다.

내가 원했던 것은 각 셀의 색상을 월 평균보다 4 배 작은 값으로 변경하는 것입니다. 지금까지 제 코드는 이렇게 보였습니다. 각 평균은 원했던 것처럼 계산되었습니다.하지만 셀을 한 열의 평균과 비교하는 방법을 알아낼 수는 없었습니다. 지금.

Sub MonthAverage() 
    Dim Data As Variant 
    Set Data = Selection 
    Dim rows As Integer 
    Dim columns As Integer 

    rows = Data.rows.Count 
    columns = Data.columns.Count 

    Dim average As Double 

    For j = 1 To columns 
     average = 0# 

     For i = 1 To rows 
      average = average + Data.Cells(i, j) 
     Next 

     average = average/rows 

     For Each cell In Data.Cells 
      If cell.Value <= average/4 Then cell.Interior.Color = RGB(0, 0, 255) 
     Next 

     MsgBox average 'just to make sure I got the averages correctly 
    Next 
End Sub 

Answer 1

내가 대신 현재 Selection의 ActiveSheet에서 작동하도록 코드를 수정했습니다. 이 코드는 ActiveSheet의 각 열을 반복하며 평균보다 4 배 작은 각 셀의 색을 지정합니다.

Sub MonthAverageV2() 
    Dim ws As Worksheet 
    Dim ThresholdVal As Double 
    Dim i As Integer 
    Dim j As Integer 
    Dim r As Integer 

    Set ws = ActiveSheet 

    'Loop columns 
    For i = 1 To ws.Cells(1, ws.columns.Count).End(xlToLeft).Column 
     r = ws.Cells(ws.rows.Count, i).End(xlUp).Row 
     'Column average 
     ThresholdVal = Application.WorksheetFunction.average(ws.Range(ws.Cells(2, i).Address & ":" & ws.Cells(r, i).Address)) * 0.25 
     Debug.Print ThresholdVal 
     'Loop rows 
     For j = 2 To r 
      If ws.Cells(j, i).Value < ThresholdVal Then 
       ws.Cells(j, i).Interior.Color = RGB(0, 0, 255) 
      End If 
     Next j 
    Next i 
End Sub 

또한 각 열의 평균을 계산하려면 Application.WorksheetFunction.average을 사용합니다.