매크로를 사용하여 Excel 파일의 데이터 바꾸기

Question

2 차원 배열에 데이터가 포함 된 Excel 파일이 있습니다. 내가 원하는 무엇

테이블 (토토, 또는 타타, 또는 티티)의 컬럼의 헤더 별표를 '*'대체 할 수있는 매크로를 만드는 것입니다.

Answer 1

사용하여 바로 워크 시트 도구 (NO VBA) :

• Ctrl-F
• 찾기 = ~ *
• Find All
• Ctrl-A 모든 검색 결과
• Close을 선택하는 어떤 대화 찾기
• 두 번째 행에 머리글이 있다고 가정하고 커서가 있다고 가정합니다. 또는 열 C의 어딘가에서 땅 (광산, 두 번 YMMV했다), 유형 =C$2
• 을 눌러 Ctrl-Enter

Answer 2

좋아요?

Option Explicit 

Sub Sample() 
    Dim oRange As Range, aCell As Range, bCell As Range 
    Dim ws As Worksheet 
    Dim ExitLoop As Boolean 

    On Error GoTo Whoa 

    '~~> Change this to the relevant sheet name 
    Set ws = Worksheets("Sheet1") 

    Set oRange = ws.Cells 

    Set aCell = oRange.Find(What:="~*", LookIn:=xlValues, _ 
       LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, _ 
       MatchCase:=False, SearchFormat:=False) 

    If Not aCell Is Nothing Then 
     Set bCell = aCell 
     '~~> Assuming that the headers are in row 2 
     aCell.Value = Cells(2, aCell.Column) 
     Do While ExitLoop = False 
      Set aCell = oRange.FindNext(After:=aCell) 

      If Not aCell Is Nothing Then 
       If aCell.Address = bCell.Address Then Exit Do 
       '~~> Assuming that the headers are in row 2 
       aCell.Value = Cells(2, aCell.Column) 
      Else 
       ExitLoop = True 
      End If 
     Loop 
    End If 
    Exit Sub 
Whoa: 
    MsgBox Err.Description 
End Sub 

Answer 3

여기에 나와있는 간단한 방법이 있습니다.

i = 3 
While Cells(2, i).Value <> "" 
    Range(Cells(3, i), Cells(6, i)).Select 

    Selection.Replace What:="~*", Replacement:=Cells(2, i).Value, LookAt:=xlPart, _ 
    SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _ 
    ReplaceFormat:=False 
    i = i + 1 
Wend 

셀 (x, y) : x는 행을 참조하고, y는 열을 참조합니다.

코드가 적절한 범위를 선택하게하려면이 기본 기본 대신에보다 정교한 범위 선택을 사용할 수 있습니다.

Excel에서 구현하려면 코드 창을 열고 원하는 매크로/서브 루틴에이 코드를 붙여 넣기 만하면됩니다.