xsl - div로 각 for의 각 2 개 항목을 감싸기

Question

나는 xsl : for-each를 갖고 있으며 div에 2 개의 항목을 모두 포장하고 싶습니다. 그렇게하는 방법?

<xsl:for-each select="$datapath/PackageInfoList/PackageInfo"> 

<!-- lots of html in here --> 

</xsl:for-each> 

그래서 결과는 다음과 같습니다

<div> 
<!-- lots of html in here --> 
<!-- lots of html in here --> 
</div> 
<div> 
<!-- lots of html in here --> 
<!-- lots of html in here --> 
</div> 

Answer 1

이 등 핸들 위치 1, 3, 5,에 요소에 대한 실행이

<xsl:for-each select="$datapath/PackageInfoList/PackageInfo[position() mod 2 = 1]"> 
    <div> 
    <!-- lots of html in here --> 

    <!-- do something with following-sibling::PackageInfo[1] --> 
    </div> 
</xsl:for-each> 

처럼 홀수 <PackageInfo> 요소를 선택 각각 수동으로 <PackageInfo>을 따르십시오.

---

더 관용적

<xsl:template match="/"> 
    <xsl:apply-templates select="$datapath/PackageInfoList/PackageInfo" mode="group2" /> 
</xsl:template> 

<xsl:template match="PackageInfo" mode="group2"> 
    <xsl:if test="position() mod 2 = 1"> 
    <div> 
     <xsl:apply-templates select=". | following-sibling::PackageInfo[1]" /> 
    </div> 
    </xsl:if> 
</xsl:template> 

<xsl:template match="PackageInfo"> 
    <!-- lots of html in here --> 
</xsl:template> 

유연

<xsl:template match="/"> 
    <xsl:apply-templates select="$datapath/PackageInfoList/PackageInfo" mode="group"> 
    <xsl:with-param name="groupcount" select="2" /> 
    </xsl:apply-templates> 
</xsl:template> 

<xsl:template match="PackageInfo" mode="group"> 
    <xsl:param name="groupcount" select="2" /> 

    <xsl:if test="position() mod $groupcount = 1"> 
    <div> 
     <xsl:apply-templates select=". | following-sibling::PackageInfo[position() &lt; $groupcount]" /> 
    </div> 
    </xsl:if> 
</xsl:template> 

<xsl:template match="PackageInfo"> 
    <!-- lots of html in here --> 
</xsl:template>