큰 문제가 있습니다 : TDictionary 및 Delphi 2010에서!

Question

동적으로로드 된 DLL에서 호스트 프로그램의 TDictionary 변수에 액세스하려고 할 때 매우 심각한 문제가 발생합니다. 여기에 완전한 코드가 있습니다. 누구든지 도움을 줄 수 있습니까? 감사!

=========== 메인 프로그램 프로젝트 소스 코드 ===================

program main; 

uses 
    ShareMem, 
    Forms, 
    uMain in 'uMain.pas' {Form1}, 
    uCommon in 'uCommon.pas'; 

{$R *.res} 

begin 
    Application.Initialize; 
    Application.MainFormOnTaskbar := True; 
    Application.CreateForm(TForm1, Form1); 
    Application.Run; 
end. 

==== ========== 부 uMain ================

unit uMain; 

interface 

uses 
    Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, 
    Dialogs, StdCtrls, uCommon; 

type 
    TForm1 = class(TForm) 
    Button1: TButton; 
    procedure Button1Click(Sender: TObject); 
    private 
    { Private declarations } 
    public 
    { Public declarations } 
    end; 


var 
    Form1: TForm1; 


implementation 

{$R *.dfm} 


type 
    Tfoo = function(ADic: TMyDic): string; stdcall; 

procedure TForm1.Button1Click(Sender: TObject); 
var 
    Dic: TMyDic; 
    HLib: THandle; 
    foo: Tfoo; 
begin 
    Dic := TMyDic.Create; 
    try 
    Dic.Add(1, 'World!'); 
    Dic.Add(2, 'Hello, '); 

    HLib := LoadLibrary('Mydll.dll'); 
    try 
     @foo := GetProcAddress(HLib, 'foo'); 
     ShowMessage(foo(Dic)); 
    finally 
     FreeLibrary(HLib); 
    end; 
    finally 
    Dic.Free; 
    end; 
end; 

end. 

=============== == dll 프로젝트 소스 코드 ===================

library MyDll; 

uses 
    ShareMem, 
    SysUtils, 
    Classes, 
    uCommon in 'uCommon.pas'; 

function foo(ADic: TMyDic):string; stdcall; 
var 
    I: Integer; 
    S: string; 
begin 
    for I in ADic.Keys do 
    begin 
    S := S + ADic[I]; 
    end; 
    Result := s; 
end; 


exports 
    foo; 

end. 

============== unit uCommon ==============

unit uCommon; 

interface 
uses 
    SysUtils, Generics.Collections; 

type 
    TMyDic = TDictionary<Integer, string>; 



implementation 

end. 

Answer 1

예외가 발생합니까? 액세스 위반 또는 잘못된 포인터 작업 일 수 있습니까?

DLL에 자체 메모리 관리자가있는 경우 Delphi와 DLL간에 문자열과 개체를 공유 할 수 없습니다. Delphi 2010을 사용하고 있기 때문에 기본적으로 FastMM이 설치되어 있어야합니다. 의 첫 번째 항목으로 "SimpleShareMem"을 추가하면 DLL과 EXE 모두에 대해 목록이 사용되며 문제가 해결되지 않는지 확인하십시오.

편집 : 당신은 DLL을 언로드 후에는 dic.free를 호출하고

: 포스터에서 추가 정보에 대응. 메모리 관리자를 공유하더라도 액세스 위반이 발생할 수 있습니다. 이유가 여기 있습니다.

무료 호출 TObject.Destroy는 가상 메서드입니다. 컴파일러는 객체의 Virtual Method Table에서 코드를 찾아 봅니다. 그러나 VMT는 메모리 관리자가 할당 한 공유 메모리가 아니라 모듈에 특정한 정적 메모리에 저장됩니다. DLL을 언로드하고 개체의 VMT 포인터 아래에서 깔개를 당겨서 가상 메서드를 호출하려고하면 액세스 위반이 발생합니다.

DLL을 언로드하기 전에 을 호출하기 전에을 호출하여이 문제를 해결할 수 있습니다. 또는 DLL 대신 런타임 패키지를 사용할 수 있습니다. DLL을 사용하기 전에 언로드되지 않는 외부 패키지에 개체의 VMT를 저장하여이 문제를 해결할 수 있습니다.

Answer 2

실행 파일과 일반 DLL간에 개체 인스턴스를 전달하지 않는 것이 좋습니다. 주로 당신이 겪고있는 정확한 이유 때문입니다. DLL이 다시 빌드되고 일부 호환되지 않는 미묘한 방법으로 개체를 변경 한 경우 어떻게됩니까?

Mason이 지적했듯이 패키지는 응용 프로그램을 모듈로 분할하는 기본 방법입니다.

Answer 3

나는 마침내 진짜 문제가 무엇인지 발견했습니다! 다음과 같이 보인다 : "for..in을 키는"루프 TDictionary는 데이터 필드 FKeyCollection에 대한 인스턴스를 생성하게됩니다 : DLL이 언로드 그래서 때, FKeyCollection도 해제됩니다 가리키는 메모리는, 따라서

function TDictionary<TKey,TValue>.GetKeys: TKeyCollection; 
begin 
    if FKeyCollection = nil then 
    FKeyCollection := TKeyCollection.Create(Self); 
    Result := FKeyCollection; 
end; 

왼쪽 "매달린 포인터".

destructor TDictionary<TKey,TValue>.Destroy; 
begin 
    Clear; 
    FKeyCollection.Free; //here will throw an exception 
    FValueCollection.Free; 
    inherited; 
end;