범위를 기준으로 필터링 열 VBA

Question

현재는 unlike the data presented here이 아닌 메인 프레임의 데이터로 작업하고 있습니다. 이 경우, 내 기준과 목표 데이터 세트에 대해 100-AAA와 유사한 문자열이 있습니다. 비슷한 솔루션을 찾았지만 VBA에 대한 범위 질문에서 직접 필터를 찾지 못했습니다.

다양한 범위의 기준에 따라 큰 데이터 집합을 필터링하려고합니다.

Sub FilterTest1() 

Dim RngOne As Range 
Dim LastCell As Long 

Sheets("Criteria").Activate 
Sheets("Criteria").Select 
Range("A1").Select 

LastCell = Application.WorksheetFunction.CountA(ActiveSheet.Range("A:A")) 

Set RngOne = ActiveSheet.Range("A2:A" & LastCell) 

Sheets("Sheet 1").Activate 
Sheets("Sheet 1").Select 

With ActiveSheet 
    If .FilterMode Then 
    .ShowAllData 
    End If 
End With 

Columns("A:A").Select 
Selection.AutoFilter 
ActiveSheet.Range("A:A").AutoFilter Field:=1, Criteria1:=RngOne, Operator:=xlOr 

End Sub 

불행하게도, 세포 내 범위는 데이터를 필터링하지 않는 경우에도, 다음과 같이, 원래, 나는 별도의 클래스/서브 루틴의 컬렉션과 함께 연주하기 시작,하지만 난 하나의 서브 루틴 내에서 범위의 사용으로 압축 Operator:=xlOr과 같은 기준을 사용하면 기준에 사용 된 마지막 셀 값만 표시됩니다. VBA 코드가 실패하지 않습니다 - 그냥 범위를 기반으로 제대로 필터링하지 않습니다.

나는 간단한 해결책이 존재한다는 것을 확신하지만 나는 그것을 꽤 볼 수 없다.

Answer 1

현재 라인 :

ActiveSheet.Range("A:A").AutoFilter Field:=1, Criteria1:=RngOne, Operator:=xlOr 

은하지 않는 범위 내에서 각각의 값으로하는 Range 객체에 의해 첫 번째 필드를 필터링하기 위해 노력하고있다.

값을 배열로로드 한 다음 배열을 필터 조건에 전달하여이 작업을 수행하는 한 가지 방법을 제공했습니다. 당신 (그리고 미래에 다른 사람을) 도움을 주목할 필요가

몇 가지 포인트 :

• 나는 매크로 레코더를 사용하여 객체의 선택에 필터링 할 올바른 구문의 배웠습니다.
• 이 사이트는 배열 트릭에 대해 배울 수 있도록 도와주었습니다. Pass Array to Filter Criteria
• 불필요한 선택 진술 등을 제거하여 코드를 더욱 빠르고 효율적으로 정리했습니다. (아니 큰 코드의이 작은 비트에 대한 거래,하지만 연습에서 점점 더 큰 프로젝트에 당신을 도울 것입니다!)

코드 아래 :

Sub FilterTest1() 

Dim RngOne As Range, cell As Range 
Dim LastCell As Long 
Dim arrList() As String, lngCnt As Long 

With Sheets("Criteria") 
    LastCell = .Range("A" & Sheets("Criteria").Rows.Count).End(xlUp).Row 
    Set RngOne = .Range("A2:A" & LastCell) 
End With 

'load values into an array 
lngCnt = 0 
For Each cell In RngOne 
    ReDim Preserve arrList(lngCnt) 
    arrList(lngCnt) = cell.Text 
    lngCnt = lngCnt + 1 
Next 


With Sheets("Sheet 1") 

    If .FilterMode Then .ShowAllData 

    .Range("A:A").AutoFilter Field:=1, Criteria1:=arrList, Operator:=xlFilterValues 

End With 

End Sub 

Answer 2

에주의해야 할 일이 있다는 것입니다 Criteria1에는 문자열 변수가 인수로 필요합니다. 배열에 범위를 할당 한 다음 string 배열을 조건에 전달할 수 있습니다. 또 다른주의 사항은 기준에 배열을 전달하는 것입니다. 제 지식은 열이 아니라 행에 있어야합니다. StringArray(3,0) 대신 StringArray(0,3)입니다. 그러므로 왜 당신은 당신의 범위에서 마지막 가치를 얻고 있었습니까? 행으로 변환하려면 Application.Transpose(StringArray)을 사용하면됩니다.

이 작은 코드는 저에게 유용하며 더 큰 배열로 쉽게 확장됩니다.

Sub test() 
Dim StringArray(0, 1 To 3) As String 'This is a fixed dimension of an array, you can easily change to dynamic by using the ReDim statement. 
ActiveSheet.AutoFilterMode = False 'To reset autofilter 

Range("D3:D5").Select 

For c = 1 To 3 'Step through the range that you wish to use as the criteria. 
StringArray(0, c) = CStr(Selection(c, 1).Value) 
Next 

Range("A:A").AutoFilter Field:=1, Criteria1:=StringArray, Operator:=xlFilterValues 

End Sub