액션 스크립트 : Adobe Flash CS4에서 사운드 멈춤

Question

동시에 모든 사운드를 중단하지 않고 CS4에서 특정 사운드를 중단하고 싶습니다. 이 문제에 대한 답을 찾기 위해 많은 것을 둘러 보았고 끝내지 않는 엄청난 점보를 많이 얻었 기 때문에 복사하고 붙여 넣을 수있는 간단한 것을 갖는 것이 좋을 것입니다. 감사합니다.

Answer 1

AS2 또는 AS3의 어떤 버전의 ActionScript를 사용하고 있습니까?

어떻게 소리를 들으십니까? 타임 라인의 키 프레임에 앉아 있습니까? ActionScript를 가져 와서 라이브러리에서 재생하려면 ActionScript를 사용하고 있습니까? 의 타임 라인에, 당신은 당신이 나중에 개별적으로 타겟팅 할 수 있도록, 그것을 재생하기 위해 액션 스크립트를 사용해야합니다 경우

(타임 라인 코드 편집)

OK, 그것을 중지합니다.

먼저 라이브러리로 가서 사운드를 마우스 오른쪽 버튼으로 클릭하고 속성을 편집하십시오. 당신은 actionscript를 위해 그것을 내 보내고, 'MyGreatSound'와 같은 독특한 액션 스크립트 식별자를주고 싶습니다. 공백이 없으며 한 단어 만 허용됩니다.

키 프레임에서 소리를 나갑니다.

다음으로 사운드의 시작 부분에 해당하는 키 프레임을 액션 레이어에 만들고 붙여 넣습니다. (이 경우 라이브러리에서 'MyGreatSound'라는 식별자를 사용한다고 가정합니다.)

var myChannel:SoundChannel = new SoundChannel(); 
var mySound:Sound = new MyGreatSound(); 
myChannel = mySound.play(0); 

이렇게하면 소리가 재생됩니다.

소리를 멈추려는 타임 라인의 지점에 해당하는 다른 키 프레임을 만듭니다.

다음에 붙여 넣으십시오.

myChannel.stop(); 

범위와 관련하여 문제가 발생할 수 있습니다. 여기

좀 더 예 : http://www.republicofcode.com/tutorials/flash/as3sound/

Answer 2

는 SoundChannel.stop()에서보세요.

이

package { 
    import flash.display.Sprite; 
    import flash.media.Sound; 
    import flash.media.SoundChannel; 
    import flash.net.URLLoader; 
    import flash.net.URLRequest; 
    import flash.text.TextField; 
    import flash.events.MouseEvent; 
    import flash.text.TextFieldAutoSize; 

    public class SoundChannel_stopExample extends Sprite { 
     private var snd:Sound = new Sound(); 
     private var channel:SoundChannel = new SoundChannel(); 
     private var button:TextField = new TextField(); 

     public function SoundChannel_stopExample() { 
      var req:URLRequest = new URLRequest("MySound.mp3"); 
      snd.load(req); 

      button.x = 10; 
      button.y = 10; 
      button.text = "PLAY"; 
      button.border = true; 
      button.background = true; 
      button.selectable = false; 
      button.autoSize = TextFieldAutoSize.CENTER; 

      button.addEventListener(MouseEvent.CLICK, clickHandler); 

      this.addChild(button); 
     } 

     private function clickHandler(e:MouseEvent):void { 
      var pausePosition:int = channel.position; 

      if(button.text == "PLAY") { 
       channel = snd.play(pausePosition); 
       button.text = "PAUSE"; 
      } 
      else { 
       channel.stop(); 
       button.text = "PLAY"; 
      } 
     } 
    } 
} 

원본 : Adobe Livedocs - flash.media.SoundChannel

(기본적으로 당신이 Sound 당신의 SoundChannel에 할당 한 다음 전체 채널을 중지

예제 코드를 사용하고 변경할 수있는 제공된다 소리 자체는 아닙니다.)