페이지 번호를 페이지 목록에서 찾으십시오.

Question

주어진 ID를 가진 행을 포함하는 페이지 번호 (페이지 목록에서)를 확인하는 방법이 있습니까? 당신이 ORDER BY는별로 정렬하는지에 대한 정확한 확인하면이 같은

Answer 1

뭔가 T-SQL에서 작동합니다 :

DECLARE @RowId INT = 55 
    , @PageSize INT = 10; 

DECLARE @Data TABLE 
(
    Id INT IDENTITY(1,1) 
    , Value INT 
) 

INSERT @Data 
SELECT 
    CAST(V.number AS INT) 
FROM master..spt_values V 
WHERE V.[type] = 'P' 
    AND CAST(V.number AS INT) BETWEEN 1 AND 100 

;WITH RankedData AS 
(
    SELECT 
     ROW_NUMBER() OVER(ORDER BY D.Value) AS Row 
     , D.Id 
    FROM 
     @Data D 
) 
SELECT 
    (SELECT Row FROM RankedData WHERE Id = @RowId)/@PageSize 

Answer 2

declare @Foo as table (FooId int identity, Bar varchar(16)) 
insert into @Foo (Bar) values ('this'), ('is'), ('some'), ('sample'), ('data'), ('eh?') 

declare @PageSize int = 3 

-- Display the page numbers. Note that there must be an explicit order. 
select FooId, Bar, (RN + @PageSize - 1)/@PageSize as Page 
    from (
    select FooId, Bar, Row_Number() over (order by Bar) as RN 
    from @Foo 
    ) as Janet 

-- Retrieve a single page number based on a FooId . 
select FooId, Bar, (RN + @PageSize - 1)/@PageSize as Page 
    from (
    select FooId, Bar, Row_Number() over (order by Bar) as RN 
    from @Foo 
    ) as Janet 
    where FooId = 3